Τώρα είναι Παρ 29 Μαρ 2024 01:17 am

Όλοι οι χρόνοι είναι UTC + 2 ώρες [ DST ]




Δημιουργία νέου θέματος Απαντήστε στο θέμα  [ 1 Δημοσίευση ] 
Συγγραφέας Μήνυμα
 Θέμα δημοσίευσης: Προγραμμα Κρεμαλας
ΔημοσίευσηΔημοσιεύτηκε: Σάβ 01 Νοέμ 2008 03:33 pm 
Χωρίς σύνδεση

Εγγραφή: Τρί 22 Απρ 2008 02:55 pm
Δημοσιεύσεις: 12
Syntax: [ Download ] [ Hide ]
ΠΡΟΓΡΑΜΜΑ ΚΡΕΜΑΛΑ
ΜΕΤΑΒΛΗΤΕΣ
  ΧΑΡΑΚΤΗΡΕΣ:Χ
  ΑΡΧΕΙΑ ΧΑΡΑΚΤΗΡΩΝ: ΛΕΞ
  ΑΡΧΕΙΑ ΑΚΕΡΑΙΩΝ: ΑΡ
ΑΡΧΗ
  ΣΥΣΧΕΤΙΣΕ_ΑΡΧΕΙΟ ΛΕΞ,'C:\words.gm'
  ΣΥΣΧΕΤΙΣΕ_ΑΡΧΕΙΟ ΑΡ,'C:\nums.gm'
  ΑΝ ΥΠΑΡΧΕΙ_ΑΡΧΕΙΟ ('C:\words.gm')=ΨΕΥΔΗΣ ΤΟΤΕ
    ΔΗΜΙΟΥΡΓΗΣΕ_ΑΡΧΕΙΟ ΛΕΞ
    ΚΛΕΙΣΕ_ΑΡΧΕΙΟ ΛΕΞ
  ΤΕΛΟΣ_ΑΝ
  ΑΝ ΥΠΑΡΧΕΙ_ΑΡΧΕΙΟ ('C:\nums.gm')=ΨΕΥΔΗΣ ΤΟΤΕ
    ΔΗΜΙΟΥΡΓΗΣΕ_ΑΡΧΕΙΟ ΑΡ
    ΚΛΕΙΣΕ_ΑΡΧΕΙΟ ΑΡ
  ΤΕΛΟΣ_ΑΝ
  ΑΝΟΙΞΕ_ΑΡΧΕΙΟ ΑΡ
  ΑΝΟΙΞΕ_ΑΡΧΕΙΟ ΛΕΞ
  ΑΝ ΜΕΓΕΘΟΣ_ΑΡΧΕΙΟΥ(ΛΕΞ)=0 ΤΟΤΕ
    ΚΑΛΕΣΕ ΑΡΧΙΚΑ
  ΤΕΛΟΣ_ΑΝ
  ΑΡΧΗ_ΕΠΑΝΑΛΗΨΗΣ
    ΑΡΧΗ_ΕΠΑΝΑΛΗΨΗΣ
      ΓΡΑΨΕ '1.Εκτελεση'
      ΓΡΑΨΕ '2.Διαμορφωη'
      ΓΡΑΨΕ '3.Τυχαια "ταξινομιση" λεξεων/φρασεων'
      ΓΡΑΨΕ '4.Στατιστικα'
      ΓΡΑΨΕ '5.Εξοδος'
      ΔΙΑΒΑΣΕ Χ
      ΚΑΘΑΡΙΣΕ_ΟΘΟΝΗ
    ΜΕΧΡΙΣ_ΟΤΟΥ Χ='3' Η Χ='1' Η Χ='2' Η Χ='4' Η Χ='5'
    ΑΝ Χ='1' ΤΟΤΕ
      ΚΑΛΕΣΕ ΕΚΤΕΛ
    ΑΛΛΙΩΣ_ΑΝ Χ='2' ΤΟΤΕ
      ΓΡΑΨΕ 'Δωσε κωδικο'
      ΔΙΑΒΑΣΕ Χ
      ΚΑΘΑΡΙΣΕ_ΟΘΟΝΗ
      ΑΝ ΣΩΣΤΟΣ(Χ)=ΑΛΗΘΗΣ ΤΟΤΕ
        ΚΑΛΕΣΕ ΔΙΑΜ
      ΑΛΛΙΩΣ_ΑΝ ΣΩΣΤΟΣ(Χ)=ΨΕΥΔΗΣ ΚΑΙ Χ='3' ΤΟΤΕ
        Χ <-- '0'
      ΤΕΛΟΣ_ΑΝ
    ΑΛΛΙΩΣ_ΑΝ Χ='4' ΤΟΤΕ
      ΚΑΛΕΣΕ ΣΤΑΤΙΣΤΙΚΑ
    ΑΛΛΙΩΣ_ΑΝ Χ='3' ΤΟΤΕ
      ΚΑΛΕΣΕ ΤΑΞΙΝ
    ΤΕΛΟΣ_ΑΝ
    ΚΑΘΑΡΙΣΕ_ΟΘΟΝΗ
  ΜΕΧΡΙΣ_ΟΤΟΥ Χ='5'
  ΚΛΕΙΣΕ_ΑΡΧΕΙΟ ΛΕΞ
  ΚΛΕΙΣΕ_ΑΡΧΕΙΟ ΑΡ
  ΚΛΕΙΣΕ_ΠΑΡΑΘΥΡΟ
ΤΕΛΟΣ_ΠΡΟΓΡΑΜΜΑΤΟΣ


ΔΙΑΔΙΚΑΣΙΑ ΕΚΤΕΛ
ΜΕΤΑΒΛΗΤΕΣ
  ΑΚΕΡΑΙΕΣ:ΜΑΧ,ΜΕΓ,Ε,Λ,ΛΓ,ΣΓ,ΕΛ_Ξ[24],ΚΕΝΑ,ΜΑΧ_ΛΓ
  ΧΑΡΑΚΤΗΡΕΣ:Γ,ΛΕΞΗ
  ΛΟΓΙΚΕΣ:ΛΑΘΟΣ,ΞΑΝΑ
ΑΡΧΗ
  ΜΑΧ <-- ΜΕΓΕΘΟΣ_ΑΡΧΕΙΟΥ (ΛΕΞ)
  ΑΝ ΜΑΧ>=2 ΤΟΤΕ
    Λ <-- 1
    ΑΡΧΗ_ΕΠΑΝΑΛΗΨΗΣ
      ΓΙΑ Ε ΑΠΟ 1 ΜΕΧΡΙ 24
        ΕΛ_Ξ[Ε] <-- 0
      ΤΕΛΟΣ_ΕΠΑΝΑΛΗΨΗΣ
      ΚΑΘΑΡΙΣΕ_ΟΘΟΝΗ
      Λ <-- Λ+1
      ΔΙΑΤΡΕΞΕ_ΑΡΧΕΙΟ ΛΕΞ,Λ
      ΔΙΑΒΑΣΕ_ΑΡΧΕΙΟ ΛΕΞ,ΛΕΞΗ
      ΚΕΝΑ <-- ΠΟΣΑ_ΚΕΝΑ(ΛΕΞΗ)
      ΣΓ <-- ΚΕΝΑ
      ΜΕΓ <-- ΜΗΚΟΣ_ΧΑΡ(ΛΕΞΗ)
      !Μεγιστος αριθμος λαθος γραμματων
      ΜΑΧ_ΛΓ <-- Α_Μ(ΜΕΓ*5/3)
!Μεγιστος αριθμος λαθος γραμματων
      ΛΓ <-- 0
      ΓΙΑ Ε ΑΠΟ 1 ΜΕΧΡΙ ΜΕΓ
        ΠΗΓΑΙΝΕ_ΧΥ 2*Ε-1,3
        ΑΝ ΛΕΞΗ[Ε]<>' ' ΤΟΤΕ
          ΓΡΑΨΕ '_'
        ΤΕΛΟΣ_ΑΝ
      ΤΕΛΟΣ_ΕΠΑΝΑΛΗΨΗΣ
      ΠΗΓΑΙΝΕ_ΧΥ 30,1
      ΓΡΑΨΕ '>Λαθη:',ΛΓ,'/',ΜΑΧ_ΛΓ
      ΠΗΓΑΙΝΕ_ΧΥ 1,1
      ΓΡΑΨΕ '>Λεξεις που εχεις βρει:'-2
      ΠΗΓΑΙΝΕ_ΧΥ 1,5
      ΓΡΑΨΕ 'Δωσε ενα γραμμα ("ΤΕΛΟΣ!" για εξοδο)'
      ΑΡΧΗ_ΕΠΑΝΑΛΗΨΗΣ
        ΠΗΓΑΙΝΕ_ΧΥ 1,6
        ΓΡΑΨΕ '     '
        ΚΑΛΕΣΕ ΕΙΣΟΔΟΣ(Γ,ΕΛ_Ξ)
        ΑΝ Γ<>'ΤΕΛΟΣ!'  ΤΟΤΕ
          ΛΑΘΟΣ <-- ΑΛΗΘΗΣ
          ΓΙΑ Ε ΑΠΟ 1 ΜΕΧΡΙ ΜΕΓ
            ΑΝ ΛΕΞΗ[Ε]=Γ ΤΟΤΕ
              ΠΗΓΑΙΝΕ_ΧΥ 2*Ε-1,2
              ΓΡΑΨΕ ΛΕΞΗ[Ε]
              ΣΓ <-- ΣΓ+1
              ΛΑΘΟΣ <-- ΨΕΥΔΗΣ
            ΤΕΛΟΣ_ΑΝ
          ΤΕΛΟΣ_ΕΠΑΝΑΛΗΨΗΣ
          ΑΝ ΛΑΘΟΣ=ΑΛΗΘΗΣ ΤΟΤΕ
            ΛΓ <-- ΛΓ+1
            ΠΗΓΑΙΝΕ_ΧΥ 30,1
            ΓΡΑΨΕ 'Λαθη:',ΛΓ,'/',ΜΑΧ_ΛΓ
          ΤΕΛΟΣ_ΑΝ
          ΚΑΛΕΣΕ ΣΤΑΤ_ΔΙΑΜ(ΛΑΘΟΣ,ΣΓ,ΛΓ,ΜΕΓ,ΜΑΧ_ΛΓ)
        ΤΕΛΟΣ_ΑΝ
      ΜΕΧΡΙΣ_ΟΤΟΥ ΛΓ=ΜΑΧ_ΛΓ Η ΣΓ=ΜΕΓ  Η Γ='ΤΕΛΟΣ!'
      ΠΗΓΑΙΝΕ_ΧΥ 1,9
      ΓΡΑΨΕ '=================> Αποτελεσμα:'
      ΑΝ ΣΓ=ΜΕΓ ΤΟΤΕ
        ΠΗΓΑΙΝΕ_ΧΥ 32,9
        ΓΡΑΨΕ 'Νικησες !'
      ΑΛΛΙΩΣ_ΑΝ ΛΓ=ΜΑΧ_ΛΓ ΤΟΤΕ
        ΠΗΓΑΙΝΕ_ΧΥ 32,9
        ΓΡΑΨΕ 'Εχασες !'
      ΑΛΛΙΩΣ_ΑΝ Γ='ΤΕΛΟΣ!' ΤΟΤΕ
        ΠΗΓΑΙΝΕ_ΧΥ 32,9
        ΓΡΑΨΕ 'Τιποτα.'
      ΤΕΛΟΣ_ΑΝ
      ΠΗΓΑΙΝΕ_ΧΥ 1,10
      ΓΡΑΨΕ '<Enter> για συνεχεια     '
      ΔΙΑΒΑΣΕ ΛΕΞΗ
    ΜΕΧΡΙΣ_ΟΤΟΥ Λ=ΜΑΧ Η ΛΓ=ΜΑΧ_ΛΓ Η Γ='ΤΕΛΟΣ!'
  ΑΛΛΙΩΣ
    ΓΡΑΨΕ 'Δεν υπαρχουν καταχωρημενες λεξεις'
    ΓΡΑΨΕ '<Enter> για συνεχεια'
    ΔΙΑΒΑΣΕ Γ
  ΤΕΛΟΣ_ΑΝ
ΤΕΛΟΣ_ΔΙΑΔΙΚΑΣΙΑΣ


ΔΙΑΔΙΚΑΣΙΑ ΣΤΑΤ_ΔΙΑΜ(ΛΑΘΟΣ,ΣΓ,ΛΓ,ΜΕΓ,ΜΑΧ_ΛΓ)
ΜΕΤΑΒΛΗΤΕΣ
  ΑΚΕΡΑΙΕΣ:ΣΓ,ΜΕΓ,Ι,ΛΓ,ΜΑΧ_ΛΓ
  ΛΟΓΙΚΕΣ:ΛΑΘΟΣ
ΑΡΧΗ
  ΑΝ ΣΓ=ΜΕΓ ΤΟΤΕ
    ΔΙΑΤΡΕΞΕ_ΑΡΧΕΙΟ ΑΡ,1
    ΔΙΑΒΑΣΕ_ΑΡΧΕΙΟ ΑΡ,Ι
    Ι <-- Ι+1
    ΔΙΑΤΡΕΞΕ_ΑΡΧΕΙΟ ΑΡ,1
    ΓΡΑΨΕ_ΑΡΧΕΙΟ ΑΡ,Ι
  ΤΕΛΟΣ_ΑΝ
  ΑΝ ΛΓ=ΜΑΧ_ΛΓ ΤΟΤΕ
    ΔΙΑΤΡΕΞΕ_ΑΡΧΕΙΟ ΑΡ,2
    ΔΙΑΒΑΣΕ_ΑΡΧΕΙΟ ΑΡ,Ι
    Ι <-- Ι+1
    ΔΙΑΤΡΕΞΕ_ΑΡΧΕΙΟ ΑΡ,2
    ΓΡΑΨΕ_ΑΡΧΕΙΟ ΑΡ,Ι
  ΤΕΛΟΣ_ΑΝ
  ΑΝ ΛΑΘΟΣ=ΨΕΥΔΗΣ ΤΟΤΕ
    ΔΙΑΤΡΕΞΕ_ΑΡΧΕΙΟ ΑΡ,3
    ΔΙΑΒΑΣΕ_ΑΡΧΕΙΟ ΑΡ,Ι
    Ι <-- Ι+1
    ΔΙΑΤΡΕΞΕ_ΑΡΧΕΙΟ ΑΡ,3
    ΓΡΑΨΕ_ΑΡΧΕΙΟ ΑΡ,Ι
  ΑΛΛΙΩΣ
    ΔΙΑΤΡΕΞΕ_ΑΡΧΕΙΟ ΑΡ,4
    ΔΙΑΒΑΣΕ_ΑΡΧΕΙΟ ΑΡ,Ι
    Ι <-- Ι+1
    ΔΙΑΤΡΕΞΕ_ΑΡΧΕΙΟ ΑΡ,4
    ΓΡΑΨΕ_ΑΡΧΕΙΟ ΑΡ,Ι
  ΤΕΛΟΣ_ΑΝ
ΤΕΛΟΣ_ΔΙΑΔΙΚΑΣΙΑΣ

ΣΥΝΑΡΤΗΣΗ ΠΟΣΑ_ΚΕΝΑ(ΛΕΞΗ):ΑΚΕΡΑΙΑ
ΜΕΤΑΒΛΗΤΕΣ
  ΑΚΕΡΑΙΕΣ:ΚΕΝΑ,Ι,ΜΕΓ
  ΧΑΡΑΚΤΗΡΕΣ:ΛΕΞΗ
ΑΡΧΗ
  ΚΕΝΑ <-- 0
  ΜΕΓ <-- ΜΗΚΟΣ_ΧΑΡ(ΛΕΞΗ)
  ΓΙΑ Ι ΑΠΟ 1 ΜΕΧΡΙ ΜΕΓ
    ΑΝ ΛΕΞΗ[Ι]=' ' ΤΟΤΕ
      ΚΕΝΑ <-- ΚΕΝΑ+1
    ΤΕΛΟΣ_ΑΝ
  ΤΕΛΟΣ_ΕΠΑΝΑΛΗΨΗΣ
  ΠΟΣΑ_ΚΕΝΑ <-- ΚΕΝΑ
ΤΕΛΟΣ_ΣΥΝΑΡΤΗΣΗΣ

ΔΙΑΔΙΚΑΣΙΑ ΕΙΣΟΔΟΣ(Γ,ΕΛ_Ξ)
ΜΕΤΑΒΛΗΤΕΣ
  ΑΚΕΡΑΙΕΣ:ΕΛ_Ξ[24]
  ΛΟΓΙΚΕΣ:ΞΑΝΑ
  ΧΑΡΑΚΤΗΡΕΣ:Γ
ΑΡΧΗ
  ΑΡΧΗ_ΕΠΑΝΑΛΗΨΗΣ
    ΠΗΓΑΙΝΕ_ΧΥ 1,6
    ΓΡΑΨΕ '                                                '
    ΠΗΓΑΙΝΕ_ΧΥ 1,6
    ΔΙΑΒΑΣΕ Γ
    Γ <-- Μ_Κ(Γ)
    ΑΝ Γ<>'ΤΕΛΟΣ!' ΤΟΤΕ
      ΞΑΝΑ <-- ΨΕΥΔΗΣ
      ΑΝ Γ='Α' ΚΑΙ  ΕΛ_Ξ[1]=1 ΤΟΤΕ
        ΞΑΝΑ <-- ΑΛΗΘΗΣ
      ΑΛΛΙΩΣ_ΑΝ Γ='Β' ΚΑΙ ΕΛ_Ξ[2]=1 ΤΟΤΕ
        ΞΑΝΑ <-- ΑΛΗΘΗΣ
      ΑΛΛΙΩΣ_ΑΝ Γ='Γ' ΚΑΙ ΕΛ_Ξ[3]=1 ΤΟΤΕ
        ΞΑΝΑ <-- ΑΛΗΘΗΣ
      ΑΛΛΙΩΣ_ΑΝ Γ='Δ' ΚΑΙ ΕΛ_Ξ[4]=1 ΤΟΤΕ
        ΞΑΝΑ <-- ΑΛΗΘΗΣ
      ΑΛΛΙΩΣ_ΑΝ Γ='Ε' ΚΑΙ ΕΛ_Ξ[5]=1 ΤΟΤΕ
        ΞΑΝΑ <-- ΑΛΗΘΗΣ
      ΑΛΛΙΩΣ_ΑΝ Γ='Ζ' ΚΑΙ ΕΛ_Ξ[6]=1 ΤΟΤΕ
        ΞΑΝΑ <-- ΑΛΗΘΗΣ
      ΑΛΛΙΩΣ_ΑΝ Γ='Η' ΚΑΙ ΕΛ_Ξ[7]=1 ΤΟΤΕ
        ΞΑΝΑ <-- ΑΛΗΘΗΣ
      ΑΛΛΙΩΣ_ΑΝ Γ='Θ' ΚΑΙ ΕΛ_Ξ[8]=1 ΤΟΤΕ
        ΞΑΝΑ <-- ΑΛΗΘΗΣ
      ΑΛΛΙΩΣ_ΑΝ Γ='Ι' ΚΑΙ ΕΛ_Ξ[9]=1 ΤΟΤΕ
        ΞΑΝΑ <-- ΑΛΗΘΗΣ
      ΑΛΛΙΩΣ_ΑΝ Γ='Κ' ΚΑΙ ΕΛ_Ξ[10]=1 ΤΟΤΕ
        ΞΑΝΑ <-- ΑΛΗΘΗΣ
      ΑΛΛΙΩΣ_ΑΝ Γ='Λ' ΚΑΙ ΕΛ_Ξ[11]=1 ΤΟΤΕ
        ΞΑΝΑ <-- ΑΛΗΘΗΣ
      ΑΛΛΙΩΣ_ΑΝ Γ='Μ' ΚΑΙ ΕΛ_Ξ[12]=1 ΤΟΤΕ
        ΞΑΝΑ <-- ΑΛΗΘΗΣ
      ΑΛΛΙΩΣ_ΑΝ Γ='Ν' ΚΑΙ ΕΛ_Ξ[13]=1 ΤΟΤΕ
        ΞΑΝΑ <-- ΑΛΗΘΗΣ
      ΑΛΛΙΩΣ_ΑΝ Γ='Ξ' ΚΑΙ ΕΛ_Ξ[14]=1 ΤΟΤΕ
        ΞΑΝΑ <-- ΑΛΗΘΗΣ
      ΑΛΛΙΩΣ_ΑΝ Γ='Ο' ΚΑΙ ΕΛ_Ξ[15]=1 ΤΟΤΕ
        ΞΑΝΑ <-- ΑΛΗΘΗΣ
      ΑΛΛΙΩΣ_ΑΝ Γ='Π' ΚΑΙ ΕΛ_Ξ[16]=1 ΤΟΤΕ
        ΞΑΝΑ <-- ΑΛΗΘΗΣ
      ΑΛΛΙΩΣ_ΑΝ Γ='Ρ' ΚΑΙ ΕΛ_Ξ[17]=1 ΤΟΤΕ
        ΞΑΝΑ <-- ΑΛΗΘΗΣ
      ΑΛΛΙΩΣ_ΑΝ Γ='Σ' ΚΑΙ ΕΛ_Ξ[18]=1 ΤΟΤΕ
        ΞΑΝΑ <-- ΑΛΗΘΗΣ
      ΑΛΛΙΩΣ_ΑΝ Γ='Τ' ΚΑΙ ΕΛ_Ξ[19]=1 ΤΟΤΕ
        ΞΑΝΑ <-- ΑΛΗΘΗΣ
      ΑΛΛΙΩΣ_ΑΝ Γ='Υ' ΚΑΙ ΕΛ_Ξ[20]=1 ΤΟΤΕ
        ΞΑΝΑ <-- ΑΛΗΘΗΣ
      ΑΛΛΙΩΣ_ΑΝ Γ='Φ' ΚΑΙ ΕΛ_Ξ[21]=1 ΤΟΤΕ
        ΞΑΝΑ <-- ΑΛΗΘΗΣ
      ΑΛΛΙΩΣ_ΑΝ Γ='Χ' ΚΑΙ ΕΛ_Ξ[22]=1 ΤΟΤΕ
        ΞΑΝΑ <-- ΑΛΗΘΗΣ
      ΑΛΛΙΩΣ_ΑΝ Γ='Ψ' ΚΑΙ ΕΛ_Ξ[23]=1 ΤΟΤΕ
        ΞΑΝΑ <-- ΑΛΗΘΗΣ
      ΑΛΛΙΩΣ_ΑΝ Γ='Ω' ΚΑΙ ΕΛ_Ξ[24]=1 ΤΟΤΕ
        ΞΑΝΑ <-- ΑΛΗΘΗΣ
      ΤΕΛΟΣ_ΑΝ
      ΑΝ ΞΑΝΑ=ΨΕΥΔΗΣ ΤΟΤΕ
        ΑΝ Γ='Α' ΤΟΤΕ
          ΕΛ_Ξ[1] <-- 1
        ΑΛΛΙΩΣ_ΑΝ Γ='Β' ΤΟΤΕ
          ΕΛ_Ξ[2] <-- 1
        ΑΛΛΙΩΣ_ΑΝ Γ='Γ' ΤΟΤΕ
          ΕΛ_Ξ[3] <-- 1
        ΑΛΛΙΩΣ_ΑΝ Γ='Δ' ΤΟΤΕ
          ΕΛ_Ξ[4] <-- 1
        ΑΛΛΙΩΣ_ΑΝ Γ='Ε' ΤΟΤΕ
          ΕΛ_Ξ[5] <-- 1
        ΑΛΛΙΩΣ_ΑΝ Γ='Ζ' ΤΟΤΕ
          ΕΛ_Ξ[6] <-- 1
        ΑΛΛΙΩΣ_ΑΝ Γ='Η' ΤΟΤΕ
          ΕΛ_Ξ[7] <-- 1
        ΑΛΛΙΩΣ_ΑΝ Γ='Θ' ΤΟΤΕ
          ΕΛ_Ξ[8] <-- 1
        ΑΛΛΙΩΣ_ΑΝ Γ='Ι' ΤΟΤΕ
          ΕΛ_Ξ[9] <-- 1
        ΑΛΛΙΩΣ_ΑΝ Γ='Κ' ΤΟΤΕ
          ΕΛ_Ξ[10] <-- 1
        ΑΛΛΙΩΣ_ΑΝ Γ='Λ' ΤΟΤΕ
          ΕΛ_Ξ[11] <-- 1
        ΑΛΛΙΩΣ_ΑΝ Γ='Μ' ΤΟΤΕ
          ΕΛ_Ξ[12] <-- 1
        ΑΛΛΙΩΣ_ΑΝ Γ='Ν' ΤΟΤΕ
          ΕΛ_Ξ[13] <-- 1
        ΑΛΛΙΩΣ_ΑΝ Γ='Ξ' ΤΟΤΕ
          ΕΛ_Ξ[14] <-- 1
        ΑΛΛΙΩΣ_ΑΝ Γ='Ο' ΤΟΤΕ
          ΕΛ_Ξ[15] <-- 1
        ΑΛΛΙΩΣ_ΑΝ Γ='Π' ΤΟΤΕ
          ΕΛ_Ξ[16] <-- 1
        ΑΛΛΙΩΣ_ΑΝ Γ='Ρ' ΤΟΤΕ
          ΕΛ_Ξ[17] <-- 1
        ΑΛΛΙΩΣ_ΑΝ Γ='Σ' ΤΟΤΕ
          ΕΛ_Ξ[18] <-- 1
        ΑΛΛΙΩΣ_ΑΝ Γ='Τ' ΤΟΤΕ
          ΕΛ_Ξ[19] <-- 1
        ΑΛΛΙΩΣ_ΑΝ Γ='Υ' ΤΟΤΕ
          ΕΛ_Ξ[20] <-- 1
        ΑΛΛΙΩΣ_ΑΝ Γ='Φ' ΤΟΤΕ
          ΕΛ_Ξ[21] <-- 1
        ΑΛΛΙΩΣ_ΑΝ Γ='Χ' ΤΟΤΕ
          ΕΛ_Ξ[22] <-- 1
        ΑΛΛΙΩΣ_ΑΝ Γ='Ψ' ΤΟΤΕ
          ΕΛ_Ξ[23] <-- 1
        ΑΛΛΙΩΣ_ΑΝ Γ='Ω' ΤΟΤΕ
          ΕΛ_Ξ[24] <-- 1
        ΤΕΛΟΣ_ΑΝ
      ΤΕΛΟΣ_ΑΝ
      ΠΗΓΑΙΝΕ_ΧΥ 1,8
      ΑΝ ΞΑΝΑ=ΑΛΗΘΗΣ ΤΟΤΕ
        ΓΡΑΨΕ 'Το εχεις ξαναδοκιμασει'
      ΑΛΛΙΩΣ
        ΓΡΑΨΕ '                          '
      ΤΕΛΟΣ_ΑΝ
      ΑΝ ΜΗΚΟΣ_ΧΑΡ(Γ)<>1 ΤΟΤΕ
        ΓΡΑΨΕ 'Ενα γραμμα καθε φορα'
      ΑΛΛΙΩΣ
        ΓΡΑΨΕ '                    '
      ΤΕΛΟΣ_ΑΝ
      ΑΝ  ΑΠΟΔΕΚΤΟ(Γ)=ΨΕΥΔΗΣ Η Γ=' ' ΤΟΤΕ
        ΓΡΑΨΕ 'Μη αποδεκτος χαρακτηρας'
      ΑΛΛΙΩΣ
        ΓΡΑΨΕ '                       '
      ΤΕΛΟΣ_ΑΝ
    ΤΕΛΟΣ_ΑΝ
  ΜΕΧΡΙΣ_ΟΤΟΥ ΜΗΚΟΣ_ΧΑΡ(Γ)=1 ΚΑΙ ΞΑΝΑ=ΨΕΥΔΗΣ ΚΑΙ Γ<>' ' ΚΑΙ ΑΠΟΔΕΚΤΟ(Γ)=ΑΛΗΘΗΣ Η Γ='ΤΕΛΟΣ!'
ΤΕΛΟΣ_ΔΙΑΔΙΚΑΣΙΑΣ


ΔΙΑΔΙΚΑΣΙΑ ΑΡΧΙΚΑ
ΜΕΤΑΒΛΗΤΕΣ
  ΑΚΕΡΑΙΕΣ:Ι,ΜΗΔ
  ΧΑΡΑΚΤΗΡΕΣ:Τ,Κ,Χ
ΑΡΧΗ
  ΜΗΔ <-- 0
  ΔΙΑΤΡΕΞΕ_ΑΡΧΕΙΟ ΑΡ,1
  ΓΙΑ Ι ΑΠΟ 1 ΜΕΧΡΙ 4
    ΓΡΑΨΕ_ΑΡΧΕΙΟ ΑΡ,ΜΗΔ
  ΤΕΛΟΣ_ΕΠΑΝΑΛΗΨΗΣ
  ΑΡΧΗ_ΕΠΑΝΑΛΗΨΗΣ
    ΓΡΑΨΕ 'Δωσε κωδικο'
    ΔΙΑΒΑΣΕ Κ
    ΓΡΑΨΕ 'Ξανα για επαλληθευση'
    ΔΙΑΒΑΣΕ Τ
    ΚΑΘΑΡΙΣΕ_ΟΘΟΝΗ
  ΜΕΧΡΙΣ_ΟΤΟΥ Τ=Κ
  ΔΙΑΤΡΕΞΕ_ΑΡΧΕΙΟ ΛΕΞ,1
  ΓΡΑΨΕ_ΑΡΧΕΙΟ ΛΕΞ,Κ
  ΓΡΑΨΕ 'Ο κωδικος ειναι:'
  ΓΡΑΨΕ '<Enter> για συνεχεια'
  ΔΙΑΒΑΣΕ Τ
  ΚΑΘΑΡΙΣΕ_ΟΘΟΝΗ
ΤΕΛΟΣ_ΔΙΑΔΙΚΑΣΙΑΣ

ΣΥΝΑΡΤΗΣΗ ΣΩΣΤΟΣ(Χ):ΛΟΓΙΚΗ
ΜΕΤΑΒΛΗΤΕΣ
  ΧΑΡΑΚΤΗΡΕΣ:Χ,ΑΡΧ
ΑΡΧΗ
  ΔΙΑΤΡΕΞΕ_ΑΡΧΕΙΟ ΛΕΞ,1
  ΔΙΑΒΑΣΕ_ΑΡΧΕΙΟ ΛΕΞ,ΑΡΧ
  ΑΝ Χ=ΑΡΧ ΤΟΤΕ
    ΣΩΣΤΟΣ <-- ΑΛΗΘΗΣ
  ΑΛΛΙΩΣ
    ΣΩΣΤΟΣ <-- ΨΕΥΔΗΣ
  ΤΕΛΟΣ_ΑΝ
ΤΕΛΟΣ_ΣΥΝΑΡΤΗΣΗΣ



ΔΙΑΔΙΚΑΣΙΑ ΔΙΑΜ
ΜΕΤΑΒΛΗΤΕΣ
  ΑΚΕΡΑΙΕΣ:ΜΑΧ,Κ,Μ,ΘΕΣΗ
  ΧΑΡΑΚΤΗΡΕΣ:ΕΠ,Χ
ΑΡΧΗ
  ΑΡΧΗ_ΕΠΑΝΑΛΗΨΗΣ
    ΑΡΧΗ_ΕΠΑΝΑΛΗΨΗΣ
      ΚΑΘΑΡΙΣΕ_ΟΘΟΝΗ
      ΓΡΑΨΕ '1.Προσθηκη λεξεων/φρασεων'
      ΓΡΑΨΕ '2.Προβολη λεξεων/φρασεων'
      ΓΡΑΨΕ '3.Διαγραφη λεξεων/φρασεων'
      ΓΡΑΨΕ '4.Αναζητηση λεξεων/φρασεων'
      ΓΡΑΨΕ '5.Αλλαγη Κωδικου'
      ΓΡΑΨΕ '6.Εξοδος από Διαμορφωση'
      ΔΙΑΒΑΣΕ ΕΠ
      ΚΑΘΑΡΙΣΕ_ΟΘΟΝΗ
    ΜΕΧΡΙΣ_ΟΤΟΥ ΕΠ='1' Η ΕΠ='2' Η ΕΠ='3' Η ΕΠ='4' Η ΕΠ='5' Η ΕΠ='6'
    ΜΑΧ <-- ΜΕΓΕΘΟΣ_ΑΡΧΕΙΟΥ (ΛΕΞ)
    ΑΝ ΕΠ='1' ΤΟΤΕ
      ΚΑΛΕΣΕ ΠΡΟΣΘ
    ΑΛΛΙΩΣ_ΑΝ ΕΠ='2' ΤΟΤΕ
      ΚΑΛΕΣΕ ΠΡΟΒ(ΜΑΧ)
    ΑΛΛΙΩΣ_ΑΝ ΕΠ='3' ΤΟΤΕ
      ΘΕΣΗ <-- 0
      ΚΑΛΕΣΕ ΔΙΑΓ(ΜΑΧ,ΘΕΣΗ)
    ΑΛΛΙΩΣ_ΑΝ ΕΠ='4' ΤΟΤΕ
      ΚΑΛΕΣΕ ΑΝΑΖ(ΜΑΧ,ΘΕΣΗ)
    ΑΛΛΙΩΣ_ΑΝ ΕΠ='5' ΤΟΤΕ
      ΚΑΛΕΣΕ ΑΛΛΑΓΗ
    ΤΕΛΟΣ_ΑΝ
  ΜΕΧΡΙΣ_ΟΤΟΥ ΕΠ='6'
ΤΕΛΟΣ_ΔΙΑΔΙΚΑΣΙΑΣ

ΔΙΑΔΙΚΑΣΙΑ ΠΡΟΣΘ
ΜΕΤΑΒΛΗΤΕΣ
  ΑΚΕΡΑΙΕΣ:ΜΑΧ
  ΧΑΡΑΚΤΗΡΕΣ:Χ
ΑΡΧΗ
  ΑΡΧΗ_ΕΠΑΝΑΛΗΨΗΣ
    ΚΑΘΑΡΙΣΕ_ΟΘΟΝΗ
    ΜΑΧ <-- ΜΕΓΕΘΟΣ_ΑΡΧΕΙΟΥ(ΛΕΞ)
    ΓΡΑΨΕ 'Ως τωρα:',ΜΑΧ-1,'καταχωρημενες λεξεις/φρασεις'
    ΓΡΑΨΕ '<Enter> για μενου'
    ΓΡΑΨΕ_ 'Προσθηκη του:'
    ΔΙΑΒΑΣΕ Χ
    Χ <-- Μ_Κ(Χ)
    ΓΡΑΨΕ ' '
    ΑΝ Χ<>'' ΤΟΤΕ
      ΑΝ ΥΠΑΡΧΕΙ(Χ)=ΨΕΥΔΗΣ ΚΑΙ ΑΠΟΔΕΚΤΟ(Χ)=ΑΛΗΘΗΣ ΤΟΤΕ
        ΔΙΑΤΡΕΞΕ_ΑΡΧΕΙΟ ΛΕΞ,ΜΑΧ+1
        ΓΡΑΨΕ_ΑΡΧΕΙΟ ΛΕΞ,Χ
        ΓΡΑΨΕ 'Κατασταση: Καταχωρηθηκε'
      ΑΛΛΙΩΣ
        ΓΡΑΨΕ 'Κατασταση: Δεν Καταχωρηθηκε!'
        ΓΡΑΨΕ '(η λεξη/φραση ηδη υπαρχει Ή υπαρχουν μη αποδεκτοι χαρακτηρες)'
      ΤΕΛΟΣ_ΑΝ
    ΤΕΛΟΣ_ΑΝ
    ΑΡΧΗ_ΕΠΑΝΑΛΗΨΗΣ
      ΓΡΑΨΕ '==============================='
      ΓΡΑΨΕ '<Enter> για προσθηκη νεας'
      ΓΡΑΨΕ '"ΤΕΛΟΣ!" για εξοδο από Προσθηκη'
      ΔΙΑΒΑΣΕ Χ
    ΜΕΧΡΙΣ_ΟΤΟΥ Χ='' Η Χ='ΤΕΛΟΣ!'
  ΜΕΧΡΙΣ_ΟΤΟΥ Χ='ΤΕΛΟΣ!'
ΤΕΛΟΣ_ΔΙΑΔΙΚΑΣΙΑΣ


ΔΙΑΔΙΚΑΣΙΑ ΠΡΟΒ(ΜΑΧ)
ΜΕΤΑΒΛΗΤΕΣ
  ΑΚΕΡΑΙΕΣ:ΜΑΧ,Κ,Μ
  ΧΑΡΑΚΤΗΡΕΣ:Χ,ΕΠ
ΑΡΧΗ
  ΚΑΘΑΡΙΣΕ_ΟΘΟΝΗ
  ΑΝ ΜΑΧ>=2 ΤΟΤΕ
    Κ <-- 1
    Μ <-- 0
    ΔΙΑΤΡΕΞΕ_ΑΡΧΕΙΟ ΛΕΞ,2
    ΑΡΧΗ_ΕΠΑΝΑΛΗΨΗΣ
      Κ <-- Κ+1
      ΔΙΑΒΑΣΕ_ΑΡΧΕΙΟ ΛΕΞ,Χ
      ΓΡΑΨΕ Κ-1,'από',ΜΑΧ-1,'.'
      Μ <-- Μ+1
      ΑΝ Μ=21 ΤΟΤΕ
        ΓΡΑΨΕ '============================='
        ΓΡΑΨΕ '<Enter> για συνεχεια προβολης'
        ΓΡΑΨΕ '2.Για τερματισμο'
        ΑΡΧΗ_ΕΠΑΝΑΛΗΨΗΣ
          ΔΙΑΒΑΣΕ Χ
        ΜΕΧΡΙΣ_ΟΤΟΥ Χ='' Η Χ='2'
        Μ <-- 0
        ΚΑΘΑΡΙΣΕ_ΟΘΟΝΗ
      ΤΕΛΟΣ_ΑΝ
    ΜΕΧΡΙΣ_ΟΤΟΥ Χ='2' Η Κ=ΜΑΧ
    ΓΡΑΨΕ '======================'
    ΓΡΑΨΕ 'Η προβολη ολοκληρωθηκε'
    ΓΡΑΨΕ '<Enter> για συνεχεια'
    ΔΙΑΒΑΣΕ ΕΠ
  ΑΛΛΙΩΣ
    ΓΡΑΨΕ 'Δεν υπαρχουν καταχωρημενες λεξεις'
    ΓΡΑΨΕ '<Enter> για συνεχεια'
    ΔΙΑΒΑΣΕ Χ
  ΤΕΛΟΣ_ΑΝ
ΤΕΛΟΣ_ΔΙΑΔΙΚΑΣΙΑΣ

ΔΙΑΔΙΚΑΣΙΑ ΔΙΑΓ(ΜΑΧ,ΘΕΣΗ)
ΜΕΤΑΒΛΗΤΕΣ
  ΑΚΕΡΑΙΕΣ:Ι,ΜΑΧ,Κ,ΘΕΣΗ
  ΧΑΡΑΚΤΗΡΕΣ:Χ
ΑΡΧΗ
  ΚΑΘΑΡΙΣΕ_ΟΘΟΝΗ
  ΑΝ ΜΑΧ>=2 ΤΟΤΕ
    ΑΡΧΗ_ΕΠΑΝΑΛΗΨΗΣ
      ΑΡΧΗ_ΕΠΑΝΑΛΗΨΗΣ
        ΚΑΘΑΡΙΣΕ_ΟΘΟΝΗ
        ΑΝ ΘΕΣΗ=0 ΤΟΤΕ
          ΓΡΑΨΕ_ 'Δωσε αριθμο καταχωρησης (μεγιστο',ΜΑΧ-1,'):'
          ΔΙΑΒΑΣΕ Κ
          Κ <-- Κ+1
        ΑΛΛΙΩΣ
          Κ <-- ΘΕΣΗ
        ΤΕΛΟΣ_ΑΝ
      ΜΕΧΡΙΣ_ΟΤΟΥ Κ>=2 ΚΑΙ Κ<=ΜΑΧ
      ΚΑΘΑΡΙΣΕ_ΟΘΟΝΗ
      ΔΙΑΤΡΕΞΕ_ΑΡΧΕΙΟ ΛΕΞ,Κ
      ΔΙΑΒΑΣΕ_ΑΡΧΕΙΟ ΛΕΞ,Χ
      ΑΡΧΗ_ΕΠΑΝΑΛΗΨΗΣ
        ΓΡΑΨΕ 'Διαγραφη του: "',Χ,'" ?'
        ΓΡΑΨΕ '==============='
        ΓΡΑΨΕ '1.Οχι/Εξοδος'
        ΑΝ ΘΕΣΗ=0 ΤΟΤΕ
          ΓΡΑΨΕ '2.Επιλογη αλλης'
        ΤΕΛΟΣ_ΑΝ
        ΓΡΑΨΕ '6.Ναι'
        ΔΙΑΒΑΣΕ Χ
      ΜΕΧΡΙΣ_ΟΤΟΥ Χ='1' Η Χ='2' Η Χ='6'
    ΜΕΧΡΙΣ_ΟΤΟΥ Χ='1' Η Χ='6'
    ΑΝ Χ='6' ΤΟΤΕ
      ΓΙΑ Ι ΑΠΟ 1 ΜΕΧΡΙ ΜΑΧ-Κ
        ΔΙΑΤΡΕΞΕ_ΑΡΧΕΙΟ ΛΕΞ,Κ+Ι
        ΔΙΑΒΑΣΕ_ΑΡΧΕΙΟ ΛΕΞ,Χ
        ΔΙΑΤΡΕΞΕ_ΑΡΧΕΙΟ ΛΕΞ,Κ+Ι-1
        ΓΡΑΨΕ_ΑΡΧΕΙΟ ΛΕΞ,Χ
      ΤΕΛΟΣ_ΕΠΑΝΑΛΗΨΗΣ
      ΔΙΑΤΡΕΞΕ_ΑΡΧΕΙΟ ΛΕΞ,ΜΑΧ
      ΑΠΟΚΟΨΕ_ΑΡΧΕΙΟ ΛΕΞ
    ΤΕΛΟΣ_ΑΝ
  ΑΛΛΙΩΣ
    ΓΡΑΨΕ 'Δεν υπαρχουν καταχωρημενες λεξεις'
    ΓΡΑΨΕ '<Enter> για συνεχεια'
    ΔΙΑΒΑΣΕ Χ
  ΤΕΛΟΣ_ΑΝ
ΤΕΛΟΣ_ΔΙΑΔΙΚΑΣΙΑΣ



ΔΙΑΔΙΚΑΣΙΑ ΑΝΑΖ(ΜΑΧ,ΘΕΣΗ)
ΜΕΤΑΒΛΗΤΕΣ
  ΑΚΕΡΑΙΕΣ:ΜΑΧ,Κ,ΘΕΣΗ
  ΧΑΡΑΚΤΗΡΕΣ:ΕΠ,Χ
ΑΡΧΗ
  ΑΝ ΜΑΧ>=2 ΤΟΤΕ
    ΑΡΧΗ_ΕΠΑΝΑΛΗΨΗΣ
      ΚΑΘΑΡΙΣΕ_ΟΘΟΝΗ
      Κ <-- 1
      ΓΡΑΨΕ_ 'Λεξη/φραση προς αναζητηση:'
      ΔΙΑΒΑΣΕ ΕΠ
      ΕΠ <-- Μ_Κ(ΕΠ)
      ΘΕΣΗ <-- 0
      ΑΝ ΕΠ<>'ΤΕΛΟΣ!' ΤΟΤΕ
        ΔΙΑΤΡΕΞΕ_ΑΡΧΕΙΟ ΛΕΞ,2
        ΑΡΧΗ_ΕΠΑΝΑΛΗΨΗΣ
          Κ <-- Κ+1
          ΔΙΑΒΑΣΕ_ΑΡΧΕΙΟ ΛΕΞ,Χ
          ΑΝ Χ=ΕΠ ΤΟΤΕ
            ΓΡΑΨΕ 'Υπαρχει στην θεση:'-1,'του αρχειου'
            ΘΕΣΗ <-- Κ
          ΤΕΛΟΣ_ΑΝ
        ΜΕΧΡΙΣ_ΟΤΟΥ Χ=ΕΠ Η Κ=ΜΑΧ
        ΑΝ ΘΕΣΗ=0 ΚΑΙ ΕΠ<>'' ΤΟΤΕ
          ΓΡΑΨΕ 'Δεν βρεθηκε'
        ΤΕΛΟΣ_ΑΝ
        ΓΡΑΨΕ ' '
        ΓΡΑΨΕ '===================='
        ΓΡΑΨΕ '<Enter> για επαναληψη'
        ΓΡΑΨΕ '"ΤΕΛΟΣ!" για εξοδο'
        ΑΝ ΘΕΣΗ<>0 ΤΟΤΕ
          ΓΡΑΨΕ '2.Διαγραφη λεξης/φρασης'
        ΤΕΛΟΣ_ΑΝ
        ΔΙΑΒΑΣΕ ΕΠ
        ΑΝ ΕΠ='2' ΚΑΙ ΘΕΣΗ<>0 ΤΟΤΕ
          ΚΑΛΕΣΕ ΔΙΑΓ(ΜΑΧ,ΘΕΣΗ)
        ΤΕΛΟΣ_ΑΝ
      ΤΕΛΟΣ_ΑΝ
    ΜΕΧΡΙΣ_ΟΤΟΥ ΕΠ='ΤΕΛΟΣ!'
  ΑΛΛΙΩΣ
    ΓΡΑΨΕ 'Δεν υπαρχουν καταχωρημενες λεξεις'
    ΓΡΑΨΕ '<Enter> για συνεχεια'
    ΔΙΑΒΑΣΕ Χ
  ΤΕΛΟΣ_ΑΝ
ΤΕΛΟΣ_ΔΙΑΔΙΚΑΣΙΑΣ







ΔΙΑΔΙΚΑΣΙΑ ΑΛΛΑΓΗ
ΜΕΤΑΒΛΗΤΕΣ
  ΧΑΡΑΚΤΗΡΕΣ:ΕΠ,Χ,Σ
ΑΡΧΗ
  ΚΑΘΑΡΙΣΕ_ΟΘΟΝΗ
  ΓΡΑΨΕ_ 'Τρεχων κωδικος:'
  ΔΙΑΒΑΣΕ ΕΠ
  ΑΝ ΣΩΣΤΟΣ(ΕΠ)=ΑΛΗΘΗΣ ΤΟΤΕ
    Σ <-- ΕΠ
    ΑΡΧΗ_ΕΠΑΝΑΛΗΨΗΣ
      ΚΑΘΑΡΙΣΕ_ΟΘΟΝΗ
      ΓΡΑΨΕ 'Τρεχων κωδικος:'
      ΓΡΑΨΕ_ 'Καινουριος κωδικος:'
      ΔΙΑΒΑΣΕ ΕΠ
      ΓΡΑΨΕ_ 'Επαλληθευση:'
      ΔΙΑΒΑΣΕ Χ
    ΜΕΧΡΙΣ_ΟΤΟΥ ΕΠ=Χ
    ΔΙΑΤΡΕΞΕ_ΑΡΧΕΙΟ ΛΕΞ,1
    ΓΡΑΨΕ_ΑΡΧΕΙΟ ΛΕΞ,Χ
    ΓΡΑΨΕ 'Νεος κωδικος:'
    ΓΡΑΨΕ '<Enter> για συνεχεια'
    ΔΙΑΒΑΣΕ ΕΠ
  ΤΕΛΟΣ_ΑΝ
ΤΕΛΟΣ_ΔΙΑΔΙΚΑΣΙΑΣ


ΣΥΝΑΡΤΗΣΗ ΥΠΑΡΧΕΙ(Χ):ΛΟΓΙΚΗ
ΜΕΤΑΒΛΗΤΕΣ
  ΑΚΕΡΑΙΕΣ:ΜΑΧ,Κ
  ΧΑΡΑΚΤΗΡΕΣ:Χ,ΑΡ_Χ
  ΛΟΓΙΚΕΣ:Λ
ΑΡΧΗ
  Λ <-- ΨΕΥΔΗΣ
  ΜΑΧ <-- ΜΕΓΕΘΟΣ_ΑΡΧΕΙΟΥ (ΛΕΞ)
  ΑΝ ΜΑΧ>=2 ΤΟΤΕ
    Κ <-- 0
    ΔΙΑΤΡΕΞΕ_ΑΡΧΕΙΟ ΛΕΞ,1
    ΑΡΧΗ_ΕΠΑΝΑΛΗΨΗΣ
      Κ <-- Κ+1
      ΔΙΑΒΑΣΕ_ΑΡΧΕΙΟ ΛΕΞ,ΑΡ_Χ
      ΑΝ ΑΡ_Χ=Χ ΤΟΤΕ
        Λ <-- ΑΛΗΘΗΣ
      ΤΕΛΟΣ_ΑΝ
    ΜΕΧΡΙΣ_ΟΤΟΥ Λ=ΑΛΗΘΗΣ Η Κ=ΜΑΧ
  ΤΕΛΟΣ_ΑΝ
  ΥΠΑΡΧΕΙ <-- Λ
ΤΕΛΟΣ_ΣΥΝΑΡΤΗΣΗΣ

ΣΥΝΑΡΤΗΣΗ ΑΠΟΔΕΚΤΟ(Χ):ΛΟΓΙΚΗ
ΜΕΤΑΒΛΗΤΕΣ
  ΛΟΓΙΚΕΣ:Λ
  ΧΑΡΑΚΤΗΡΕΣ:Χ
  ΑΚΕΡΑΙΕΣ:ΜΑΧ,Κ
ΑΡΧΗ
  Λ <-- ΑΛΗΘΗΣ
  ΜΑΧ <-- ΜΗΚΟΣ_ΧΑΡ(Χ)
  Κ <-- 0
  ΑΡΧΗ_ΕΠΑΝΑΛΗΨΗΣ
    Κ <-- Κ+1
    ΑΝ Χ[Κ]<>'Α' ΚΑΙ Χ[Κ]<>'Β' ΚΑΙ Χ[Κ]<>'Γ' ΚΑΙ Χ[Κ]<>'Δ' ΚΑΙ Χ[Κ]<>'Ε' ΚΑΙ  Χ[Κ]<>'Ζ' ΤΟΤΕ
      ΑΝ Χ[Κ]<>'Η' ΚΑΙ Χ[Κ]<>'Θ' ΚΑΙ Χ[Κ]<>'Ι' ΚΑΙ Χ[Κ]<>'Κ' ΚΑΙ Χ[Κ]<>'Λ' ΚΑΙ  Χ[Κ]<>'Μ' ΤΟΤΕ
        ΑΝ Χ[Κ]<>'Ν' ΚΑΙ Χ[Κ]<>'Ξ' ΚΑΙ Χ[Κ]<>'Ο' ΚΑΙ Χ[Κ]<>'Π' ΚΑΙ Χ[Κ]<>'Ρ' ΚΑΙ  Χ[Κ]<>'Σ' ΤΟΤΕ
          ΑΝ Χ[Κ]<>'Τ' ΚΑΙ Χ[Κ]<>'Υ' ΚΑΙ Χ[Κ]<>'Φ' ΚΑΙ Χ[Κ]<>'Χ' ΚΑΙ Χ[Κ]<>'Ψ' ΚΑΙ  Χ[Κ]<>'Ω' ΚΑΙ Χ[Κ]<>' ' ΤΟΤΕ
            Λ <-- ΨΕΥΔΗΣ
          ΤΕΛΟΣ_ΑΝ
        ΤΕΛΟΣ_ΑΝ
      ΤΕΛΟΣ_ΑΝ
    ΤΕΛΟΣ_ΑΝ
  ΜΕΧΡΙΣ_ΟΤΟΥ Κ=ΜΑΧ Η Λ=ΨΕΥΔΗΣ
  ΑΠΟΔΕΚΤΟ <-- Λ
ΤΕΛΟΣ_ΣΥΝΑΡΤΗΣΗΣ


ΣΥΝΑΡΤΗΣΗ Μ_Κ(Χ):ΧΑΡΑΚΤΗΡΕΣ
ΜΕΤΑΒΛΗΤΕΣ
  ΧΑΡΑΚΤΗΡΕΣ:Χ
  ΑΚΕΡΑΙΕΣ:ΜΑΧ,Κ
ΑΡΧΗ
  ΜΑΧ <-- ΜΗΚΟΣ_ΧΑΡ(Χ)
  ΓΙΑ Κ ΑΠΟ 1 ΜΕΧΡΙ ΜΑΧ
    ΑΝ Χ[Κ]='α' ΤΟΤΕ
      Χ[Κ] <-- 'Α'
    ΑΛΛΙΩΣ_ΑΝ Χ[Κ]='β' ΤΟΤΕ
      Χ[Κ] <-- 'Β'
    ΑΛΛΙΩΣ_ΑΝ Χ[Κ]='γ' ΤΟΤΕ
      Χ[Κ] <-- 'Γ'
    ΑΛΛΙΩΣ_ΑΝ Χ[Κ]='δ' ΤΟΤΕ
      Χ[Κ] <-- 'Δ'
    ΑΛΛΙΩΣ_ΑΝ Χ[Κ]='ε' ΤΟΤΕ
      Χ[Κ] <-- 'Ε'
    ΑΛΛΙΩΣ_ΑΝ Χ[Κ]='ζ' ΤΟΤΕ
      Χ[Κ] <-- 'Ζ'
    ΑΛΛΙΩΣ_ΑΝ Χ[Κ]='η' ΤΟΤΕ
      Χ[Κ] <-- 'Η'
    ΑΛΛΙΩΣ_ΑΝ Χ[Κ]='θ' ΤΟΤΕ
      Χ[Κ] <-- 'Θ'
    ΑΛΛΙΩΣ_ΑΝ Χ[Κ]='ι' ΤΟΤΕ
      Χ[Κ] <-- 'Ι'
    ΑΛΛΙΩΣ_ΑΝ Χ[Κ]='κ' ΤΟΤΕ
      Χ[Κ] <-- 'Κ'
    ΑΛΛΙΩΣ_ΑΝ Χ[Κ]='λ' ΤΟΤΕ
      Χ[Κ] <-- 'Λ'
    ΑΛΛΙΩΣ_ΑΝ Χ[Κ]='μ' ΤΟΤΕ
      Χ[Κ] <-- 'Μ'
    ΑΛΛΙΩΣ_ΑΝ Χ[Κ]='ν' ΤΟΤΕ
      Χ[Κ] <-- 'Ν'
    ΑΛΛΙΩΣ_ΑΝ Χ[Κ]='ξ' ΤΟΤΕ
      Χ[Κ] <-- 'Ξ'
    ΑΛΛΙΩΣ_ΑΝ Χ[Κ]='ο' ΤΟΤΕ
      Χ[Κ] <-- 'Ο'
    ΑΛΛΙΩΣ_ΑΝ Χ[Κ]='π' ΤΟΤΕ
      Χ[Κ] <-- 'Π'
    ΑΛΛΙΩΣ_ΑΝ Χ[Κ]='ρ' ΤΟΤΕ
      Χ[Κ] <-- 'Ρ'
    ΑΛΛΙΩΣ_ΑΝ Χ[Κ]='σ' Η Χ[Κ]='ς' ΤΟΤΕ
      Χ[Κ] <-- 'Σ'
    ΑΛΛΙΩΣ_ΑΝ Χ[Κ]='τ' ΤΟΤΕ
      Χ[Κ] <-- 'Τ'
    ΑΛΛΙΩΣ_ΑΝ Χ[Κ]='υ' ΤΟΤΕ
      Χ[Κ] <-- 'Υ'
    ΑΛΛΙΩΣ_ΑΝ Χ[Κ]='φ' ΤΟΤΕ
      Χ[Κ] <-- 'Φ'
    ΑΛΛΙΩΣ_ΑΝ Χ[Κ]='χ' ΤΟΤΕ
      Χ[Κ] <-- 'Χ'
    ΑΛΛΙΩΣ_ΑΝ Χ[Κ]='ψ' ΤΟΤΕ
      Χ[Κ] <-- 'Ψ'
    ΑΛΛΙΩΣ_ΑΝ Χ[Κ]='ω' ΤΟΤΕ
      Χ[Κ] <-- 'Ω'
    ΤΕΛΟΣ_ΑΝ
  ΤΕΛΟΣ_ΕΠΑΝΑΛΗΨΗΣ
  Μ_Κ <--  Χ
ΤΕΛΟΣ_ΣΥΝΑΡΤΗΣΗΣ





ΔΙΑΔΙΚΑΣΙΑ ΣΤΑΤΙΣΤΙΚΑ
ΜΕΤΑΒΛΗΤΕΣ
  ΑΚΕΡΑΙΕΣ:Χ1,Χ2,Χ3,Χ4
  ΧΑΡΑΚΤΗΡΕΣ:Χ
ΑΡΧΗ
  ΔΙΑΤΡΕΞΕ_ΑΡΧΕΙΟ ΑΡ,1
  ΔΙΑΒΑΣΕ_ΑΡΧΕΙΟ ΑΡ,Χ1
  ΔΙΑΤΡΕΞΕ_ΑΡΧΕΙΟ ΑΡ,2
  ΔΙΑΒΑΣΕ_ΑΡΧΕΙΟ ΑΡ,Χ2
  ΔΙΑΤΡΕΞΕ_ΑΡΧΕΙΟ ΑΡ,3
  ΔΙΑΒΑΣΕ_ΑΡΧΕΙΟ ΑΡ,Χ3
  ΔΙΑΤΡΕΞΕ_ΑΡΧΕΙΟ ΑΡ,4
  ΔΙΑΒΑΣΕ_ΑΡΧΕΙΟ ΑΡ,Χ4
  ΓΡΑΨΕ 'Νικες:',Χ1
  ΓΡΑΨΕ 'Ηττες:',Χ2
  ΠΗΓΑΙΝΕ_ΧΥ 14,1
  ΓΡΑΨΕ '# σωστων γραμματων:',Χ3
  ΠΗΓΑΙΝΕ_ΧΥ 14,2
  ΓΡΑΨΕ '# λαθος γραμματων: ',Χ4
  ΓΡΑΨΕ '===================='
  ΓΡΑΨΕ '<Enter> για συνεχεια'
  ΓΡΑΨΕ '2.Μηδενισμος'
  ΔΙΑΒΑΣΕ Χ
  ΑΝ Χ='2' ΤΟΤΕ
    ΓΡΑΨΕ_ 'Κωδικος:'
    ΔΙΑΒΑΣΕ Χ
    ΑΝ ΣΩΣΤΟΣ(Χ)=ΑΛΗΘΗΣ ΤΟΤΕ
      Χ2 <-- 0
      ΔΙΑΤΡΕΞΕ_ΑΡΧΕΙΟ ΑΡ,1
      ΓΙΑ Χ1 ΑΠΟ 1 ΜΕΧΡΙ 4
        ΓΡΑΨΕ_ΑΡΧΕΙΟ ΑΡ,Χ2
      ΤΕΛΟΣ_ΕΠΑΝΑΛΗΨΗΣ
      ΓΡΑΨΕ '===================='
      ΓΡΑΨΕ 'Ολοκληρωθηκε'
    ΑΛΛΙΩΣ
      ΓΡΑΨΕ 'Λαθος κωδικος'
    ΤΕΛΟΣ_ΑΝ
    ΓΡΑΨΕ '<Enter> για συνεχεια'
    ΔΙΑΒΑΣΕ Χ
  ΤΕΛΟΣ_ΑΝ
ΤΕΛΟΣ_ΔΙΑΔΙΚΑΣΙΑΣ



ΔΙΑΔΙΚΑΣΙΑ ΤΑΞΙΝ
ΜΕΤΑΒΛΗΤΕΣ
  ΑΚΕΡΑΙΕΣ:ΜΑΧ,Τ1,Τ2,Ι
  ΧΑΡΑΚΤΗΡΕΣ:Χ1,Χ2
ΑΡΧΗ
  ΚΑΘΑΡΙΣΕ_ΟΘΟΝΗ
  ΜΑΧ <-- ΜΕΓΕΘΟΣ_ΑΡΧΕΙΟΥ (ΛΕΞ)
  ΑΝ ΜΑΧ>=3 ΤΟΤΕ
    ΓΙΑ Ι ΑΠΟ 1 ΜΕΧΡΙ ΜΑΧ
      ΠΗΓΑΙΝΕ_ΧΥ 1,1
      ΓΡΑΨΕ 'Ολοκληρωθηκε:',100*(Ι/ΜΑΧ),'%    '
      ΑΡΧΗ_ΕΠΑΝΑΛΗΨΗΣ
        Τ1 <-- ΤΥΧΑΙΟΣ(ΜΑΧ+1)
      ΜΕΧΡΙΣ_ΟΤΟΥ Τ1<>1 ΚΑΙ Τ1<>0
      ΑΡΧΗ_ΕΠΑΝΑΛΗΨΗΣ
        Τ2 <-- ΤΥΧΑΙΟΣ(ΜΑΧ+1)
      ΜΕΧΡΙΣ_ΟΤΟΥ Τ2<>Τ1 ΚΑΙ Τ2<>1 ΚΑΙ Τ2<>0
      ΔΙΑΤΡΕΞΕ_ΑΡΧΕΙΟ ΛΕΞ,Τ1
      ΔΙΑΒΑΣΕ_ΑΡΧΕΙΟ ΛΕΞ,Χ1
      ΔΙΑΤΡΕΞΕ_ΑΡΧΕΙΟ ΛΕΞ,Τ2
      ΔΙΑΒΑΣΕ_ΑΡΧΕΙΟ ΛΕΞ,Χ2
      ΔΙΑΤΡΕΞΕ_ΑΡΧΕΙΟ ΛΕΞ,Τ1
      ΓΡΑΨΕ_ΑΡΧΕΙΟ ΛΕΞ,Χ2
      ΔΙΑΤΡΕΞΕ_ΑΡΧΕΙΟ ΛΕΞ,Τ2
      ΓΡΑΨΕ_ΑΡΧΕΙΟ ΛΕΞ,Χ1
    ΤΕΛΟΣ_ΕΠΑΝΑΛΗΨΗΣ
  ΑΛΛΙΩΣ
    ΓΡΑΨΕ 'Πρεπει να υπαρχουν τουλαχιστον 2 λεξεις/φρασεις'
  ΤΕΛΟΣ_ΑΝ
  ΓΡΑΨΕ '<Enter> για συνεχεια'
  ΔΙΑΒΑΣΕ Χ1
ΤΕΛΟΣ_ΔΙΑΔΙΚΑΣΙΑΣ


Κορυφή
 Προφίλ  
Απάντηση με παράθεση  
Τελευταίες δημοσιεύσεις:  Ταξινόμηση ανά  
Δημιουργία νέου θέματος Απαντήστε στο θέμα  [ 1 Δημοσίευση ] 

Όλοι οι χρόνοι είναι UTC + 2 ώρες [ DST ]


Μέλη σε σύνδεση

Μέλη σε αυτή την Δ. Συζήτηση: Δεν υπάρχουν εγγεγραμμένα μέλη και 7 επισκέπτες


Δεν μπορείτε να δημοσιεύετε νέα θέματα σε αυτή τη Δ. Συζήτηση
Δεν μπορείτε να απαντάτε σε θέματα σε αυτή τη Δ. Συζήτηση
Δεν μπορείτε να επεξεργάζεστε τις δημοσιεύσεις σας σε αυτή τη Δ. Συζήτηση
Δεν μπορείτε να διαγράφετε τις δημοσιεύσεις σας σε αυτή τη Δ. Συζήτηση
Δεν μπορείτε να επισυνάπτετε αρχεία σε αυτή τη Δ. Συζήτηση

Αναζήτηση για:
Μετάβαση σε:  
cron
Προβολές: