Τώρα είναι Πέμ 28 Μαρ 2024 07:15 pm

Όλοι οι χρόνοι είναι UTC + 2 ώρες [ DST ]




Δημιουργία νέου θέματος Απαντήστε στο θέμα  [ 1 Δημοσίευση ] 
Συγγραφέας Μήνυμα
 Θέμα δημοσίευσης: Formula 1 - 2007
ΔημοσίευσηΔημοσιεύτηκε: Παρ 18 Μάιος 2007 08:17 pm 
Χωρίς σύνδεση

Εγγραφή: Κυρ 12 Οκτ 2003 01:52 am
Δημοσιεύσεις: 189
Τοποθεσία: ΝΙΚΑΙΑ - ΠΕΙΡΑΙΑΣ
Syntax: [ Download ] [ Hide ]
! = ΤΕΛ03 =================================================================
! Το πρωτάθλημα της FORMULA1 του 2007 ολοκληρώθηκε σε 17 αγώνες και πήραν
! μέρος 22 οδηγοί που ανήκαν σε 11 εταιρείες. Σε κάθε αγώνα βαθμολογούνται
! οι οδηγοί που τερματίζουν στις θέσεις 1 έως και 8 με 10 , 8 , 6 , 5 , 4 ,
! 3 , 2 και 1 βαθμό αντίστοιχα.
! Να γραφεί πρόγραμμα το οποίο :
! · για κάθε οδηγό να ζητά και να καταχωρεί σε κατάλληλους πίνακες το όνομά
!   του την εταιρεία στην οποία ανήκει και τη θέση στην οποία τερμάτισε σε
!   κάθε ένα από τους αγώνες (για τους αγώνες που δεν τερμάτισε καταχωρείται
!   ως θέση το μηδέν).
! · να υπολογίζει τη βαθμολογία του πρωταθλήματος.
! · να εμφανίζει τα αποτελέσματα ταξινομημένα με βάση την τελική βαθμολογία,
!   στα οποία να φαίνεται για κάθε αθλητή το όνομά του, η εταιρεία στην
!   οποία ανήκει και αναλυτικά η θέση που πήρε σε κάθε αγώνα του πρωταθλήμα-
!   τος.
! ΠΑΡΑΤΗΡΗΣΗ : Να γίνεται έλεγχος εγκυρότητας μόνο για τη θέση τερματισμού,
!              υποθέτοντας ο χρήστης δίνει σίγουρα ακέραιο.
! =========================================================================
!
ΠΡΟΓΡΑΜΜΑ TEL_03
ΜΕΤΑΒΛΗΤΕΣ
  ΑΚΕΡΑΙΕΣ : pos[22,17] , s[22] , i , j , k , temp2
  ΧΑΡΑΚΤΗΡΕΣ : name[22] , et[22] , temp1
ΑΡΧΗ
  ΓΙΑ i ΑΠΟ 1 ΜΕΧΡΙ 22
    ΓΡΑΨΕ 'Δώσε το όνομα του οδηγού Νο :' , i
    ΔΙΑΒΑΣΕ name[i]
    ΓΡΑΨΕ 'Δώσε το όνομα της εταιρίας του'
    ΔΙΑΒΑΣΕ et[i]                                                    
    ΓΙΑ j ΑΠΟ 1 ΜΕΧΡΙ 17
      ΓΡΑΨΕ 'Δώσε τη θέση που πήρε στον αγώνα Νο :' , i
      ΓΡΑΨΕ 'Δώσε μηδέν αν δεν τερμάτισε'
      ΔΙΑΒΑΣΕ pos[i,j]
      ΟΣΟ pos[i,j] < 0 ή pos[i,j] > 22 ΕΠΑΝΑΛΑΒΕ
        ΓΡΑΨΕ 'Λάθος. Ξαναδώσε'
        ΔΙΑΒΑΣΕ pos[i,j]
      ΤΕΛΟΣ_ΕΠΑΝΑΛΗΨΗΣ
    ΤΕΛΟΣ_ΕΠΑΝΑΛΗΨΗΣ
  ΤΕΛΟΣ_ΕΠΑΝΑΛΗΨΗΣ
  ΓΙΑ i ΑΠΟ 1 ΜΕΧΡΙ 22
    s[i] <-- 0
    ΓΙΑ j ΑΠΟ 1 ΜΕΧΡΙ 17      !
      ΕΠΙΛΕΞΕ pos[i,j]        !
        ΠΕΡΙΠΤΩΣΗ 1           !
          s[i] <-- s[i] + 10  !
        ΠΕΡΙΠΤΩΣΗ 2           !======== B ΤΡΟΠΟΣ ========
          s[i] <-- s[i] + 8   !
        ΠΕΡΙΠΤΩΣΗ 3           !   ΑΝ j = 1 TOTE
          s[i] <-- s[i] + 6   !     s[i] <-- s[i] + 10
        ΠΕΡΙΠΤΩΣΗ 4           !   ΑΛΛΙΩΣ_ΑΝ j = 2 TOTE
          s[i] <-- s[i] + 5   !     s[i] <-- s[i] + 8
        ΠΕΡΙΠΤΩΣΗ 5!          !   ΑΛΛΙΩΣ_ΑΝ j > 0 ΤΟΤΕ
          s[i] <-- s[i] + 4   !     s[i] <-- s[i] + 9 - j
        ΠΕΡΙΠΤΩΣΗ 6           !   ΤΕΛΟΣ_ΑΝ
          s[i] <-- s[i] + 3   !
        ΠΕΡΙΠΤΩΣΗ 7           ! ==========================
          s[i] <-- s[i] + 2   !
        ΠΕΡΙΠΤΩΣΗ 8           !
          s[i] <-- s[i] + 1   !
      ΤΕΛΟΣ_ΕΠΙΛΟΓΩΝ          !
    ΤΕΛΟΣ_ΕΠΑΝΑΛΗΨΗΣ
  ΤΕΛΟΣ_ΕΠΑΝΑΛΗΨΗΣ
  ΓΙΑ i ΑΠΟ 2 ΜΕΧΡΙ 22
    ΓΙΑ j ΑΠΟ 22 ΜΕΧΡΙ i ΜΕ ΒΗΜΑ -1
      ΑΝ s[j-1] < s[j] ΤΟΤΕ
        temp1 <-- name[j-1]
        name[j-1] <-- name[j]
        name[j] <-- temp1
        temp1 <-- et[j-1]
        et[j-1] <-- et[j]
        et[j] <-- temp1
        temp2 <-- s[j-1]
        s[j-1] <-- s[j]
        s[j] <-- temp2
        ΓΙΑ k ΑΠΟ 1 ΜΕΧΡΙ 17
          temp2 <-- pos[j-1,k]
          pos[j-1,k] <-- pos[j,k]
          pos[j,k] <-- temp2
        ΤΕΛΟΣ_ΕΠΑΝΑΛΗΨΗΣ
      ΤΕΛΟΣ_ΑΝ
    ΤΕΛΟΣ_ΕΠΑΝΑΛΗΨΗΣ
  ΤΕΛΟΣ_ΕΠΑΝΑΛΗΨΗΣ
  ΓΙΑ i ΑΠΟ 1 ΜΕΧΡΙ 22
    ΓΡΑΨΕ name[i] , et[i] , s[i]
    ΓΙΑ j ΑΠΟ 1 ΜΕΧΡΙ 17
      ΓΡΑΨΕ pos[i,j]
    ΤΕΛΟΣ_ΕΠΑΝΑΛΗΨΗΣ
  ΤΕΛΟΣ_ΕΠΑΝΑΛΗΨΗΣ
ΤΕΛΟΣ_ΠΡΟΓΡΑΜΜΑΤΟΣ


Κορυφή
 Προφίλ  
Απάντηση με παράθεση  
Τελευταίες δημοσιεύσεις:  Ταξινόμηση ανά  
Δημιουργία νέου θέματος Απαντήστε στο θέμα  [ 1 Δημοσίευση ] 

Όλοι οι χρόνοι είναι UTC + 2 ώρες [ DST ]


Μέλη σε σύνδεση

Μέλη σε αυτή την Δ. Συζήτηση: Δεν υπάρχουν εγγεγραμμένα μέλη και 2 επισκέπτες


Δεν μπορείτε να δημοσιεύετε νέα θέματα σε αυτή τη Δ. Συζήτηση
Δεν μπορείτε να απαντάτε σε θέματα σε αυτή τη Δ. Συζήτηση
Δεν μπορείτε να επεξεργάζεστε τις δημοσιεύσεις σας σε αυτή τη Δ. Συζήτηση
Δεν μπορείτε να διαγράφετε τις δημοσιεύσεις σας σε αυτή τη Δ. Συζήτηση
Δεν μπορείτε να επισυνάπτετε αρχεία σε αυτή τη Δ. Συζήτηση

Αναζήτηση για:
Μετάβαση σε:  
cron
Προβολές: