Τώρα είναι Παρ 29 Μαρ 2024 01:51 am

Όλοι οι χρόνοι είναι UTC + 2 ώρες [ DST ]




Δημιουργία νέου θέματος Απαντήστε στο θέμα  [ 1 Δημοσίευση ] 
Συγγραφέας Μήνυμα
ΔημοσίευσηΔημοσιεύτηκε: Παρ 09 Μάιος 2003 09:31 pm 
Χωρίς σύνδεση

Εγγραφή: Πέμ 01 Μάιος 2003 10:25 pm
Δημοσιεύσεις: 38
Τοποθεσία: Καλλιθέα Αττικής
Nα μια άσκηση για το σπίτι:
Τι πρέπει να κάνουμε για να σβήσουμε μια εγγραφή (να λιγοστέψουν τελικά οι εγγραφές);
Μπορείτε να σκεφτείτε ο,τι θέλετε αρκεί να έχει λογική συνέπεια!
Η ρουτίνα ταξινόμησης είναι μια παραλλαγή του τρόπου ταξινόμησης αρχείων σε ταινίες! Από μια ταινία χώριζαν το αρχείο σε δυό και μετα από τις δυο φτιάχνανε πάλι την αρχική. Αυτό το κάνανε μέχρι το χώρισμα να βγάζει ένα κενό αρχείο και ένα γεμάτο.
Κανονικά ο αλγόριθμος δουλεύει με σειριακά αρχεία.

Syntax: [ Download ] [ Hide ]
ΠΡΟΓΡΑΜΜΑ ΑΠΟΘΗΚΗ
! ΓΙΑ ΤΗΝ ΕΚΔΟΣΗ 4 ΤΗΣ ΓΛΩΣΣΟΜΑΘΕΙΑΣ
ΣΤΑΘΕΡΕΣ
  ΟΛΑ_ΤΑ_ΕΙΔΗ = ΨΕΥΔΗΣ
  ΜΟΝΟ_ΕΚΤΟΣ_ΟΡΙΟΥ = ΑΛΗΘΗΣ
ΜΕΤΑΒΛΗΤΕΣ
  ΛΟΓΙΚΕΣ: ΤΡΟΠΟΣ

ΑΡΧΗ
  ΑΝ ΝΑΙ('ΝΑ ΔΗΜΙΟΥΡΓΗΣΩ ΝΕΑ ΑΡΧΕΙΑ') ΤΟΤΕ
    ΚΑΛΕΣΕ ΔΗΜ_ΑΡΧ
  ΤΕΛΟΣ_ΑΝ
! ΒΑΖΟΥΜΕ ΤΡΙΑ ΕΙΔΗ
  ΑΝ ΝΑΙ('ΝΑ ΒΑΛΩ ΤΡΙΑ ΕΙΔΗ') ΤΟΤΕ
    ΑΝ ΕΙΣ_ΕΙΔΟΥΣ('101.10','ΝΤΟΜΑΤΕΣ',200.3,'ΚΙΛΑ',2.4,50,'ΜΑΝΑΒ1101') ΤΟΤΕ
      ΓΡΑΨΕ 'ΚΑΤΑΧΩΡΗΣΗ ΕΙΔΟΥΣ:101.10'
    ΤΕΛΟΣ_ΑΝ
    ΑΝ ΕΙΣ_ΕΙΔΟΥΣ('101.11','ΦΥΚΙΑ',12.23,'ΚΙΛΑ',5.1,20,'ΒΟΥΤΗΧΤ03') ΤΟΤΕ
      ΓΡΑΨΕ 'ΚΑΤΑΧΩΡΗΣΗ ΕΙΔΟΥΣ:101.11'
    ΤΕΛΟΣ_ΑΝ
    ΑΝ ΕΙΣ_ΕΙΔΟΥΣ('101.03','ΚΑΛΑΘΙΑ',17.0,'ΤΕΜ.',3,10,'ΚΑΛΑΘΑΣ01') ΤΟΤΕ
      ΓΡΑΨΕ 'ΚΑΤΑΧΩΡΗΣΗ ΕΙΔΟΥΣ:101.03'
    ΤΕΛΟΣ_ΑΝ
  ΤΕΛΟΣ_ΑΝ
  ΓΡΑΨΕ 'ΑΝΑΦΟΡΑ ΑΠΟΘΗΚΗΣ'
  ΤΡΟΠΟΣ <-- ΟΛΑ_ΤΑ_ΕΙΔΗ
  ΚΑΛΕΣΕ ΑΝΑΦΟΡΑ_ΑΠΟΘΗΚΗΣ(ΤΡΟΠΟΣ)
  ΑΝ ΤΑΞΙΝΟΜΗΣΗ('C:\ALFA02','DAT') ΤΟΤΕ
    ΓΡΑΨΕ 'EKANA ΤΑΞΙΝΟΜΗΣΗ ΣΤΟΝ ΚΩΔΙΚΟ'
  ΤΕΛΟΣ_ΑΝ
  ΓΡΑΨΕ 'ΑΝΑΦΟΡΑ ΑΠΟΘΗΚΗΣ'
  ΤΡΟΠΟΣ <-- ΟΛΑ_ΤΑ_ΕΙΔΗ
  ΚΑΛΕΣΕ ΑΝΑΦΟΡΑ_ΑΠΟΘΗΚΗΣ(ΤΡΟΠΟΣ)
  ΓΡΑΨΕ 'ΜΟΝΟ ΤΑ ΕΙΔΗ ΕΚΤΟΣ ΟΡΙΟΥ'
  ΤΡΟΠΟΣ <-- ΜΟΝΟ_ΕΚΤΟΣ_ΟΡΙΟΥ
  ΚΑΛΕΣΕ ΑΝΑΦΟΡΑ_ΑΠΟΘΗΚΗΣ(ΤΡΟΠΟΣ)
  ΓΡΑΨΕ 'ΑΓΟΡΑΣΕΣ ΑΛΛΑ 100 ΚΑΛΑΘΙΑ! ΜΠΡΑΒΟ'
  ΑΝ ΕΝΗΜ_ΕΙΔΟΥΣ('101.03', 100) ΤΟΤΕ
    ΤΡΟΠΟΣ <-- ΟΛΑ_ΤΑ_ΕΙΔΗ
    ΚΑΛΕΣΕ ΑΝΑΦΟΡΑ_ΑΠΟΘΗΚΗΣ(ΤΡΟΠΟΣ)
  ΤΕΛΟΣ_ΑΝ
ΤΕΛΟΣ_ΠΡΟΓΡΑΜΜΑΤΟΣ

! βασικές συναρτήσεις
ΣΥΝΑΡΤΗΣΗ ΜΕΡΟΣ(Χ,Ι,Λ): ΧΑΡΑΚΤΗΡΑΣ

ΜΕΤΑΒΛΗΤΕΣ
  ΧΑΡΑΚΤΗΡΕΣ: Χ, Ψ
  ΑΚΕΡΑΙΕΣ: Ι,Λ
ΑΡΧΗ
  Ψ <-- ''
  ΑΝ ΜΗΚΟΣ_ΧΑΡ(Χ)>=Ι ΤΟΤΕ
    Λ <-- Ι+Λ-1
    ΑΝ ΜΗΚΟΣ_ΧΑΡ(Χ)<Λ ΤΟΤΕ
      Λ <-- ΜΗΚΟΣ_ΧΑΡ(Χ)
    ΤΕΛΟΣ_ΑΝ
    ΓΙΑ Ι ΑΠΟ Ι ΜΕΧΡΙ Λ
      Ψ <-- Ψ+Χ[Ι]
    ΤΕΛΟΣ_ΕΠΑΝΑΛΗΨΗΣ
  ΤΕΛΟΣ_ΑΝ
  ΜΕΡΟΣ <-- Ψ
ΤΕΛΟΣ_ΣΥΝΑΡΤΗΣΗΣ

!  ΑΡΙΘΜΟΣ ΣΕ ΔΥΟ ΧΑΡΑΚΤΗΡΕΣ (2 ΒΥΤΕ)

ΣΥΝΑΡΤΗΣΗ ΛΕΞΗ(Α):ΧΑΡΑΚΤΗΡΑΣ
ΜΕΤΑΒΛΗΤΕΣ
  ΑΚΕΡΑΙΕΣ: Α
ΑΡΧΗ
! κατα INTEL (msb πρώτο - lsb δεύτερο)
  ΛΕΞΗ <-- ΧΑΡ(Α DIV 256)+ΧΑΡ(Α MOD 256)
ΤΕΛΟΣ_ΣΥΝΑΡΤΗΣΗΣ

! ΛΕΞΗ ΜΗΚΟΥΣ 2 ΧΑΡΑΚΤΗΡΩΝ ΣΕ ΑΡΙΘΜΟ
ΣΥΝΑΡΤΗΣΗ ΑΚ_ΛΕΞΗ(Χ):ΑΚΕΡΑΙΑ
ΜΕΤΑΒΛΗΤΕΣ
  ΧΑΡΑΚΤΗΡΕΣ: Χ
ΑΡΧΗ
! κατα INTEL (msb πρώτο - lsb δεύτερο)
  ΑΝ ΜΗΚΟΣ_ΧΑΡ(Χ)=2 ΤΟΤΕ
    ΑΚ_ΛΕΞΗ <-- ΣΕΙΡΑ_ΧΑΡ(Χ[1])*256+ΣΕΙΡΑ_ΧΑΡ(Χ[2])
  ΑΛΛΙΩΣ
    ΑΚ_ΛΕΞΗ <-- 0
  ΤΕΛΟΣ_ΑΝ
ΤΕΛΟΣ_ΣΥΝΑΡΤΗΣΗΣ

ΣΥΝΑΡΤΗΣΗ ΠΑΡΕΜΒΟΛΗ(Χ,Ψ,Ι):ΧΑΡΑΚΤΗΡΑΣ
ΜΕΤΑΒΛΗΤΕΣ
  ΧΑΡΑΚΤΗΡΕΣ: Χ, ΑΧ, Ψ
  ΑΚΕΡΑΙΕΣ: Ι, Κ
ΑΡΧΗ
  ΑΝ Χ='' ΤΟΤΕ
    Χ <-- ' '
  ΤΕΛΟΣ_ΑΝ
  ΑΝ ΜΗΚΟΣ_ΧΑΡ(Χ)< (Ι+ΜΗΚΟΣ_ΧΑΡ(Ψ)+1) ΤΟΤΕ
    ΓΙΑ Κ ΑΠΟ ΜΗΚΟΣ_ΧΑΡ(Χ) ΜΕΧΡΙ Ι+ΜΗΚΟΣ_ΧΑΡ(Ψ)-1
      Χ <-- Χ+' '
    ΤΕΛΟΣ_ΕΠΑΝΑΛΗΨΗΣ
  ΤΕΛΟΣ_ΑΝ
  ΑΧ <-- Χ
  ΓΙΑ Κ ΑΠΟ Ι ΜΕΧΡΙ ΜΗΚΟΣ_ΧΑΡ(ΑΧ)
    ΑΝ (Κ-Ι)<ΜΗΚΟΣ_ΧΑΡ(Ψ) ΤΟΤΕ
      Χ[Κ] <-- Ψ[Κ-Ι+1]
    ΑΛΛΙΩΣ
      Χ[Κ] <-- ΑΧ[Κ]
    ΤΕΛΟΣ_ΑΝ
  ΤΕΛΟΣ_ΕΠΑΝΑΛΗΨΗΣ

  ΠΑΡΕΜΒΟΛΗ <-- Χ
ΤΕΛΟΣ_ΣΥΝΑΡΤΗΣΗΣ


ΣΥΝΑΡΤΗΣΗ ΝΑΙ(ΕΜΦΑΝΙΣΗ) :ΛΟΓΙΚΗ
ΜΕΤΑΒΛΗΤΕΣ
  ΧΑΡΑΚΤΗΡΕΣ: ΕΜΦΑΝΙΣΗ, ΝΝ
  ΛΟΓΙΚΕΣ: ΟΚ
ΑΡΧΗ
  ΑΡΧΗ_ΕΠΑΝΑΛΗΨΗΣ
    ΓΡΑΨΕ ΕΜΦΑΝΙΣΗ,'(Ν/Ο)'
    ΔΙΑΒΑΣΕ ΝΝ
    ΟΚ <-- ΨΕΥΔΗΣ
    ΑΝ (ΝΝ='N') Ή (ΝΝ='Ν') ΤΟΤΕ
      ΝΑΙ <-- ΑΛΗΘΗΣ
      ΟΚ <-- ΑΛΗΘΗΣ
    ΑΛΛΙΩΣ_ΑΝ (ΝΝ='O') Ή (ΝΝ='Ο') ΤΟΤΕ
      ΝΑΙ <-- ΨΕΥΔΗΣ
      ΟΚ <-- ΑΛΗΘΗΣ
    ΤΕΛΟΣ_ΑΝ
  ΜΕΧΡΙΣ_ΟΤΟΥ ΟΚ
ΤΕΛΟΣ_ΣΥΝΑΡΤΗΣΗΣ

ΣΥΝΑΡΤΗΣΗ ΠΕΔΙΟ(Χ,Λ):ΧΑΡΑΚΤΗΡΑΣ
ΜΕΤΑΒΛΗΤΕΣ
  ΧΑΡΑΚΤΗΡΕΣ: Χ, Ψ
  ΑΚΕΡΑΙΕΣ: Ι,Λ
ΑΡΧΗ
  Ψ <-- ''
  ΓΙΑ Ι ΑΠΟ 1 ΜΕΧΡΙ Λ
    ΑΝ ΜΗΚΟΣ_ΧΑΡ(Χ)<Ι ΤΟΤΕ
      Ψ <-- Ψ+' '
    ΑΛΛΙΩΣ
      Ψ <-- Ψ+Χ[Ι]
    ΤΕΛΟΣ_ΑΝ
  ΤΕΛΟΣ_ΕΠΑΝΑΛΗΨΗΣ
  ΠΕΔΙΟ <-- Ψ
ΤΕΛΟΣ_ΣΥΝΑΡΤΗΣΗΣ
ΣΥΝΑΡΤΗΣΗ ΑΡΧ(Ν):ΧΑΡΑΚΤΗΡΕΣ
ΜΕΤΑΒΛΗΤΕΣ
  ΑΚΕΡΑΙΕΣ: Ν
ΑΡΧΗ
  ΑΡΧ <-- 'C:\ALFA' + ΧΑΡ(48+((Ν DIV 10) MOD 10)) +ΧΑΡ(48+(Ν MOD 10))+'.DAT'
ΤΕΛΟΣ_ΣΥΝΑΡΤΗΣΗΣ

ΔΙΑΔΙΚΑΣΙΑ ΔΗΜ_ΑΡΧ
ΜΕΤΑΒΛΗΤΕΣ
  ΑΡΧΕΙΑ ΠΡΑΓΜΑΤΙΚΩΝ: Α_ΠΟΣΟΤΗΤΑ, Α_ΟΡΙΟ, Α_ΑΞΙΑ
  ΑΡΧΕΙΑ ΧΑΡΑΚΤΗΡΩΝ: Α_ΚΩΔΙΚΟΣ, Α_ΕΙΔΟΣ, Α_ΜΟΝΑΔΕΣ, Α_ΚΩΔ_ΠΡΟΜ
ΑΡΧΗ

  ΣΥΣΧΕΤΙΣΕ_ΑΡΧΕΙΟ Α_ΕΙΔΟΣ, ΑΡΧ(1)
  ΣΥΣΧΕΤΙΣΕ_ΑΡΧΕΙΟ Α_ΚΩΔΙΚΟΣ, ΑΡΧ(2)
  ΣΥΣΧΕΤΙΣΕ_ΑΡΧΕΙΟ Α_ΜΟΝΑΔΕΣ, ΑΡΧ(3)
  ΣΥΣΧΕΤΙΣΕ_ΑΡΧΕΙΟ Α_ΚΩΔ_ΠΡΟΜ, ΑΡΧ(4)
  ΣΥΣΧΕΤΙΣΕ_ΑΡΧΕΙΟ Α_ΠΟΣΟΤΗΤΑ, ΑΡΧ(5)
  ΣΥΣΧΕΤΙΣΕ_ΑΡΧΕΙΟ Α_ΟΡΙΟ, ΑΡΧ(6)
  ΣΥΣΧΕΤΙΣΕ_ΑΡΧΕΙΟ Α_ΑΞΙΑ, ΑΡΧ(7)

  ΔΗΜΙΟΥΡΓΗΣΕ_ΑΡΧΕΙΟ Α_ΕΙΔΟΣ
  ΔΗΜΙΟΥΡΓΗΣΕ_ΑΡΧΕΙΟ Α_ΚΩΔΙΚΟΣ
  ΔΗΜΙΟΥΡΓΗΣΕ_ΑΡΧΕΙΟ Α_ΜΟΝΑΔΕΣ
  ΔΗΜΙΟΥΡΓΗΣΕ_ΑΡΧΕΙΟ Α_ΚΩΔ_ΠΡΟΜ
  ΔΗΜΙΟΥΡΓΗΣΕ_ΑΡΧΕΙΟ Α_ΠΟΣΟΤΗΤΑ
  ΔΗΜΙΟΥΡΓΗΣΕ_ΑΡΧΕΙΟ Α_ΟΡΙΟ
  ΔΗΜΙΟΥΡΓΗΣΕ_ΑΡΧΕΙΟ Α_ΑΞΙΑ

  ΚΛΕΙΣΕ_ΑΡΧΕΙΟ Α_ΕΙΔΟΣ
  ΚΛΕΙΣΕ_ΑΡΧΕΙΟ Α_ΚΩΔΙΚΟΣ
  ΚΛΕΙΣΕ_ΑΡΧΕΙΟ Α_ΜΟΝΑΔΕΣ
  ΚΛΕΙΣΕ_ΑΡΧΕΙΟ Α_ΚΩΔ_ΠΡΟΜ
  ΚΛΕΙΣΕ_ΑΡΧΕΙΟ Α_ΠΟΣΟΤΗΤΑ
  ΚΛΕΙΣΕ_ΑΡΧΕΙΟ Α_ΟΡΙΟ
  ΚΛΕΙΣΕ_ΑΡΧΕΙΟ Α_ΑΞΙΑ

ΤΕΛΟΣ_ΔΙΑΔΙΚΑΣΙΑΣ

ΣΥΝΑΡΤΗΣΗ ΑΛΛΗ_ΕΓΓΡΑΦΗ(ΚΩΔΙΚΟΣ):ΛΟΓΙΚΗ
ΜΕΤΑΒΛΗΤΕΣ
  ΛΟΓΙΚΕΣ: ΟΚ
  ΧΑΡΑΚΤΗΡΕΣ: ΚΩΔΙΚΟΣ, ΚΩΔΙΚΟΣ1
  ΑΡΧΕΙΑ ΧΑΡΑΚΤΗΡΩΝ: Α_ΚΩΔΙΚΟΣ
ΑΡΧΗ
  ΟΚ <-- ΨΕΥΔΗΣ
  ΣΥΣΧΕΤΙΣΕ_ΑΡΧΕΙΟ Α_ΚΩΔΙΚΟΣ, ΑΡΧ(2)
  ΑΝΟΙΞΕ_ΑΡΧΕΙΟ Α_ΚΩΔΙΚΟΣ

  ΟΣΟ ΟΧΙ ΤΕΛΟΣ_ΑΡΧΕΙΟΥ(Α_ΚΩΔΙΚΟΣ) ΕΠΑΝΑΛΑΒΕ
    ΔΙΑΒΑΣΕ_ΑΡΧΕΙΟ Α_ΚΩΔΙΚΟΣ, ΚΩΔΙΚΟΣ1
    ΑΝ ΚΩΔΙΚΟΣ=ΜΕΡΟΣ(ΚΩΔΙΚΟΣ1,1,6) ΤΟΤΕ
      ΟΚ <-- ΑΛΗΘΗΣ
    ΤΕΛΟΣ_ΑΝ
  ΤΕΛΟΣ_ΕΠΑΝΑΛΗΨΗΣ

  ΚΛΕΙΣΕ_ΑΡΧΕΙΟ Α_ΚΩΔΙΚΟΣ
  ΑΛΛΗ_ΕΓΓΡΑΦΗ <-- ΟΚ
ΤΕΛΟΣ_ΣΥΝΑΡΤΗΣΗΣ


ΣΥΝΑΡΤΗΣΗ ΕΙΣ_ΕΙΔΟΥΣ(ΚΩΔΙΚΟΣ, ΕΙΔΟΣ, ΠΟΣΟΤΗΤΑ,ΜΟΝΑΔΕΣ, ΑΞΙΑ, ΟΡΙΟ, ΚΩΔ_ΠΡΟΜ):ΛΟΓΙΚΗ
ΜΕΤΑΒΛΗΤΕΣ
  ΠΡΑΓΜΑΤΙΚΕΣ: ΠΟΣΟΤΗΤΑ, ΟΡΙΟ, ΑΞΙΑ
  ΧΑΡΑΚΤΗΡΕΣ: ΚΩΔΙΚΟΣ, ΕΙΔΟΣ, ΜΟΝΑΔΕΣ, ΚΩΔ_ΠΡΟΜ, Ν_ΚΩΔ
  ΑΡΧΕΙΑ ΠΡΑΓΜΑΤΙΚΩΝ: Α_ΠΟΣΟΤΗΤΑ, Α_ΟΡΙΟ, Α_ΑΞΙΑ
  ΑΡΧΕΙΑ ΧΑΡΑΚΤΗΡΩΝ: Α_ΚΩΔΙΚΟΣ, Α_ΕΙΔΟΣ, Α_ΜΟΝΑΔΕΣ, Α_ΚΩΔ_ΠΡΟΜ
ΑΡΧΗ
  ΑΝ ΟΧΙ ΑΛΛΗ_ΕΓΓΡΑΦΗ(ΚΩΔΙΚΟΣ) ΤΟΤΕ
    ΣΥΣΧΕΤΙΣΕ_ΑΡΧΕΙΟ Α_ΕΙΔΟΣ, ΑΡΧ(1)
    ΣΥΣΧΕΤΙΣΕ_ΑΡΧΕΙΟ Α_ΚΩΔΙΚΟΣ, ΑΡΧ(2)
    ΣΥΣΧΕΤΙΣΕ_ΑΡΧΕΙΟ Α_ΜΟΝΑΔΕΣ, ΑΡΧ(3)
    ΣΥΣΧΕΤΙΣΕ_ΑΡΧΕΙΟ Α_ΚΩΔ_ΠΡΟΜ, ΑΡΧ(4)
    ΣΥΣΧΕΤΙΣΕ_ΑΡΧΕΙΟ Α_ΠΟΣΟΤΗΤΑ, ΑΡΧ(5)
    ΣΥΣΧΕΤΙΣΕ_ΑΡΧΕΙΟ Α_ΟΡΙΟ, ΑΡΧ(6)
    ΣΥΣΧΕΤΙΣΕ_ΑΡΧΕΙΟ Α_ΑΞΙΑ, ΑΡΧ(7)

    ΑΝΟΙΞΕ_ΑΡΧΕΙΟ Α_ΕΙΔΟΣ
    ΑΝΟΙΞΕ_ΑΡΧΕΙΟ Α_ΚΩΔΙΚΟΣ
    ΑΝΟΙΞΕ_ΑΡΧΕΙΟ Α_ΜΟΝΑΔΕΣ
    ΑΝΟΙΞΕ_ΑΡΧΕΙΟ Α_ΚΩΔ_ΠΡΟΜ
    ΑΝΟΙΞΕ_ΑΡΧΕΙΟ Α_ΠΟΣΟΤΗΤΑ
    ΑΝΟΙΞΕ_ΑΡΧΕΙΟ Α_ΟΡΙΟ
    ΑΝΟΙΞΕ_ΑΡΧΕΙΟ Α_ΑΞΙΑ


    ΔΙΕΤΡΕΞΕ_ΑΡΧΕΙΟ Α_ΕΙΔΟΣ, ΜΕΓΕΘΟΣ_ΑΡΧΕΙΟΥ(Α_ΕΙΔΟΣ)+1
    ΔΙΕΤΡΕΞΕ_ΑΡΧΕΙΟ Α_ΚΩΔΙΚΟΣ, ΜΕΓΕΘΟΣ_ΑΡΧΕΙΟΥ(Α_ΚΩΔΙΚΟΣ)+1
    ΔΙΕΤΡΕΞΕ_ΑΡΧΕΙΟ Α_ΜΟΝΑΔΕΣ, ΜΕΓΕΘΟΣ_ΑΡΧΕΙΟΥ(Α_ΜΟΝΑΔΕΣ)+1
    ΔΙΕΤΡΕΞΕ_ΑΡΧΕΙΟ Α_ΚΩΔ_ΠΡΟΜ, ΜΕΓΕΘΟΣ_ΑΡΧΕΙΟΥ(Α_ΚΩΔ_ΠΡΟΜ)+1
    ΔΙΕΤΡΕΞΕ_ΑΡΧΕΙΟ Α_ΠΟΣΟΤΗΤΑ, ΜΕΓΕΘΟΣ_ΑΡΧΕΙΟΥ(Α_ΠΟΣΟΤΗΤΑ)+1
    ΔΙΕΤΡΕΞΕ_ΑΡΧΕΙΟ Α_ΟΡΙΟ, ΜΕΓΕΘΟΣ_ΑΡΧΕΙΟΥ(Α_ΟΡΙΟ)+1
    ΔΙΕΤΡΕΞΕ_ΑΡΧΕΙΟ Α_ΑΞΙΑ, ΜΕΓΕΘΟΣ_ΑΡΧΕΙΟΥ(Α_ΑΞΙΑ)+1

    ΓΡΑΨΕ_ΑΡΧΕΙΟ Α_ΕΙΔΟΣ, ΕΙΔΟΣ
    Ν_ΚΩΔ <-- ΜΕΡΟΣ(ΠΑΡΕΜΒΟΛΗ(ΚΩΔΙΚΟΣ, ΛΕΞΗ( ΜΕΓΕΘΟΣ_ΑΡΧΕΙΟΥ(Α_ΕΙΔΟΣ) ),7),1,9)
    ΓΡΑΨΕ_ΑΡΧΕΙΟ Α_ΚΩΔΙΚΟΣ, Ν_ΚΩΔ
    ΓΡΑΨΕ_ΑΡΧΕΙΟ Α_ΜΟΝΑΔΕΣ, ΜΟΝΑΔΕΣ
    ΓΡΑΨΕ_ΑΡΧΕΙΟ Α_ΚΩΔ_ΠΡΟΜ, ΚΩΔ_ΠΡΟΜ
    ΓΡΑΨΕ_ΑΡΧΕΙΟ Α_ΠΟΣΟΤΗΤΑ, ΠΟΣΟΤΗΤΑ
    ΓΡΑΨΕ_ΑΡΧΕΙΟ Α_ΟΡΙΟ, ΟΡΙΟ
    ΓΡΑΨΕ_ΑΡΧΕΙΟ Α_ΑΞΙΑ, ΑΞΙΑ

    ΚΛΕΙΣΕ_ΑΡΧΕΙΟ Α_ΕΙΔΟΣ
    ΚΛΕΙΣΕ_ΑΡΧΕΙΟ Α_ΚΩΔΙΚΟΣ
    ΚΛΕΙΣΕ_ΑΡΧΕΙΟ Α_ΜΟΝΑΔΕΣ
    ΚΛΕΙΣΕ_ΑΡΧΕΙΟ Α_ΚΩΔ_ΠΡΟΜ
    ΚΛΕΙΣΕ_ΑΡΧΕΙΟ Α_ΠΟΣΟΤΗΤΑ
    ΚΛΕΙΣΕ_ΑΡΧΕΙΟ Α_ΟΡΙΟ
    ΚΛΕΙΣΕ_ΑΡΧΕΙΟ Α_ΑΞΙΑ

    ΕΙΣ_ΕΙΔΟΥΣ <-- ΑΛΗΘΗΣ
  ΑΛΛΙΩΣ
    ΕΙΣ_ΕΙΔΟΥΣ <-- ΨΕΥΔΗΣ
  ΤΕΛΟΣ_ΑΝ
ΤΕΛΟΣ_ΣΥΝΑΡΤΗΣΗΣ

ΣΥΝΑΡΤΗΣΗ ΕΝΗΜ_ΕΙΔΟΥΣ(ΚΩΔΙΚΟΣ, ΠΟΣΟ):ΛΟΓΙΚΗ
ΜΕΤΑΒΛΗΤΕΣ
  ΑΚΕΡΑΙΕΣ: ΕΜΜΕΣΗ_ΘΕΣΗ
  ΠΡΑΓΜΑΤΙΚΕΣ: ΠΟΣΟΤΗΤΑ, ΠΟΣΟ, ΝΕΑ_ΠΟΣΟΤΗΤΑ
  ΧΑΡΑΚΤΗΡΕΣ: ΚΩΔΙΚΟΣ, ΚΩΔΙΚΟΣ1
  ΑΡΧΕΙΑ ΠΡΑΓΜΑΤΙΚΩΝ: Α_ΠΟΣΟΤΗΤΑ
  ΑΡΧΕΙΑ ΧΑΡΑΚΤΗΡΩΝ: Α_ΚΩΔΙΚΟΣ
ΑΡΧΗ

  ΣΥΣΧΕΤΙΣΕ_ΑΡΧΕΙΟ Α_ΚΩΔΙΚΟΣ, ΑΡΧ(2)
  ΣΥΣΧΕΤΙΣΕ_ΑΡΧΕΙΟ Α_ΠΟΣΟΤΗΤΑ, ΑΡΧ(5)
  ΑΝΟΙΞΕ_ΑΡΧΕΙΟ Α_ΚΩΔΙΚΟΣ
  ΑΝΟΙΞΕ_ΑΡΧΕΙΟ Α_ΠΟΣΟΤΗΤΑ

  ΟΣΟ ΟΧΙ ΤΕΛΟΣ_ΑΡΧΕΙΟΥ(Α_ΚΩΔΙΚΟΣ) ΕΠΑΝΑΛΑΒΕ
    ΔΙΑΒΑΣΕ_ΑΡΧΕΙΟ Α_ΚΩΔΙΚΟΣ, ΚΩΔΙΚΟΣ1
    ΑΝ ΚΩΔΙΚΟΣ=ΜΕΡΟΣ(ΚΩΔΙΚΟΣ1,1,6) ΤΟΤΕ
      ΕΜΜΕΣΗ_ΘΕΣΗ <-- ΑΚ_ΛΕΞΗ(ΜΕΡΟΣ(ΚΩΔΙΚΟΣ1,7,2))
      ΔΙΕΤΡΕΞΕ_ΑΡΧΕΙΟ Α_ΠΟΣΟΤΗΤΑ, ΕΜΜΕΣΗ_ΘΕΣΗ     
      ΔΙΑΒΑΣΕ_ΑΡΧΕΙΟ Α_ΠΟΣΟΤΗΤΑ, ΠΟΣΟΤΗΤΑ
      ΔΙΕΤΡΕΞΕ_ΑΡΧΕΙΟ Α_ΠΟΣΟΤΗΤΑ, ΕΜΜΕΣΗ_ΘΕΣΗ   
      ΝΕΑ_ΠΟΣΟΤΗΤΑ <-- ΠΟΣΟΤΗΤΑ+ΠΟΣΟ
      ΓΡΑΨΕ_ΑΡΧΕΙΟ Α_ΠΟΣΟΤΗΤΑ, ΝΕΑ_ΠΟΣΟΤΗΤΑ
    ΤΕΛΟΣ_ΑΝ
  ΤΕΛΟΣ_ΕΠΑΝΑΛΗΨΗΣ

  ΚΛΕΙΣΕ_ΑΡΧΕΙΟ Α_ΚΩΔΙΚΟΣ
  ΚΛΕΙΣΕ_ΑΡΧΕΙΟ Α_ΠΟΣΟΤΗΤΑ

  ΕΝΗΜ_ΕΙΔΟΥΣ <-- ΑΛΗΘΗΣ
ΤΕΛΟΣ_ΣΥΝΑΡΤΗΣΗΣ

ΔΙΑΔΙΚΑΣΙΑ ΑΝΑΦΟΡΑ_ΑΠΟΘΗΚΗΣ(ΜΟΝΟ_ΟΡΙΟ)
ΜΕΤΑΒΛΗΤΕΣ
  ΠΡΑΓΜΑΤΙΚΕΣ: ΠΟΣΟΤΗΤΑ, ΟΡΙΟ, ΑΞΙΑ, ΤΕΛΙΚΗ_ΑΞΙΑ
  ΧΑΡΑΚΤΗΡΕΣ: ΚΩΔΙΚΟΣ, ΕΙΔΟΣ, ΜΟΝΑΔΕΣ, ΚΩΔ_ΠΡΟΜ
  ΑΚΕΡΑΙΕΣ: ΑΝΑ_ΑΡΑΔΕΣ, Ι, Μ, ΕΜΜΕΣΟ
  ΛΟΓΙΚΕΣ: ΜΟΝΟ_ΟΡΙΟ
  ΑΡΧΕΙΑ ΠΡΑΓΜΑΤΙΚΩΝ: Α_ΠΟΣΟΤΗΤΑ, Α_ΟΡΙΟ, Α_ΑΞΙΑ
  ΑΡΧΕΙΑ ΧΑΡΑΚΤΗΡΩΝ: Α_ΚΩΔΙΚΟΣ, Α_ΕΙΔΟΣ, Α_ΜΟΝΑΔΕΣ, Α_ΚΩΔ_ΠΡΟΜ
ΑΡΧΗ

  ΣΥΣΧΕΤΙΣΕ_ΑΡΧΕΙΟ Α_ΕΙΔΟΣ, ΑΡΧ(1)
  ΣΥΣΧΕΤΙΣΕ_ΑΡΧΕΙΟ Α_ΚΩΔΙΚΟΣ, ΑΡΧ(2)
  ΣΥΣΧΕΤΙΣΕ_ΑΡΧΕΙΟ Α_ΜΟΝΑΔΕΣ, ΑΡΧ(3)
  ΣΥΣΧΕΤΙΣΕ_ΑΡΧΕΙΟ Α_ΚΩΔ_ΠΡΟΜ, ΑΡΧ(4)
  ΣΥΣΧΕΤΙΣΕ_ΑΡΧΕΙΟ Α_ΠΟΣΟΤΗΤΑ, ΑΡΧ(5)
  ΣΥΣΧΕΤΙΣΕ_ΑΡΧΕΙΟ Α_ΟΡΙΟ, ΑΡΧ(6)
  ΣΥΣΧΕΤΙΣΕ_ΑΡΧΕΙΟ Α_ΑΞΙΑ, ΑΡΧ(7)

  ΑΝΟΙΞΕ_ΑΡΧΕΙΟ Α_ΕΙΔΟΣ
  ΑΝΟΙΞΕ_ΑΡΧΕΙΟ Α_ΚΩΔΙΚΟΣ
  ΑΝΟΙΞΕ_ΑΡΧΕΙΟ Α_ΜΟΝΑΔΕΣ
  ΑΝΟΙΞΕ_ΑΡΧΕΙΟ Α_ΚΩΔ_ΠΡΟΜ
  ΑΝΟΙΞΕ_ΑΡΧΕΙΟ Α_ΠΟΣΟΤΗΤΑ
  ΑΝΟΙΞΕ_ΑΡΧΕΙΟ Α_ΟΡΙΟ
  ΑΝΟΙΞΕ_ΑΡΧΕΙΟ Α_ΑΞΙΑ
  ΓΡΑΨΕ_ ΠΕΔΙΟ('ΚΩΔΙΚΟΣ',11),ΠΕΔΙΟ('ΕΙΔΟΣ',15), ΠΕΔΙΟ('ΠΟΣΟΤΗΤΑ/ΜΟΝΑΔ',16),ΠΕΔΙΟ('ΣΥΝ. ΑΞΙΑ',11)
  ΓΡΑΨΕ ΠΕΔΙΟ('ΕΛΑΧ.ΠΟΣΟΤ',11),ΠΕΔΙΟ('ΚΩΔΙΚΟΣ ΠΕΛΑΤΗ',15)

  ΑΝ ΟΧΙ ΤΕΛΟΣ_ΑΡΧΕΙΟΥ(Α_ΕΙΔΟΣ) ΤΟΤΕ
    ΓΙΑ Ι ΑΠΟ 1 ΜΕΧΡΙ ΜΕΓΕΘΟΣ_ΑΡΧΕΙΟΥ(Α_ΕΙΔΟΣ)
      ΔΙΑΒΑΣΕ_ΑΡΧΕΙΟ Α_ΚΩΔΙΚΟΣ, ΚΩΔΙΚΟΣ
      ΕΜΜΕΣΟ <-- ΑΚ_ΛΕΞΗ(ΜΕΡΟΣ(ΚΩΔΙΚΟΣ,7,2))
      ΔΙΕΤΡΕΞΕ_ΑΡΧΕΙΟ Α_ΕΙΔΟΣ, ΕΜΜΕΣΟ
      ΔΙΕΤΡΕΞΕ_ΑΡΧΕΙΟ Α_ΜΟΝΑΔΕΣ, ΕΜΜΕΣΟ
      ΔΙΕΤΡΕΞΕ_ΑΡΧΕΙΟ Α_ΚΩΔ_ΠΡΟΜ, ΕΜΜΕΣΟ
      ΔΙΕΤΡΕΞΕ_ΑΡΧΕΙΟ Α_ΠΟΣΟΤΗΤΑ, ΕΜΜΕΣΟ
      ΔΙΕΤΡΕΞΕ_ΑΡΧΕΙΟ Α_ΟΡΙΟ, ΕΜΜΕΣΟ
      ΔΙΕΤΡΕΞΕ_ΑΡΧΕΙΟ Α_ΑΞΙΑ, ΕΜΜΕΣΟ

      ΔΙΑΒΑΣΕ_ΑΡΧΕΙΟ Α_ΕΙΔΟΣ, ΕΙΔΟΣ
      ΔΙΑΒΑΣΕ_ΑΡΧΕΙΟ Α_ΜΟΝΑΔΕΣ, ΜΟΝΑΔΕΣ
      ΔΙΑΒΑΣΕ_ΑΡΧΕΙΟ Α_ΚΩΔ_ΠΡΟΜ, ΚΩΔ_ΠΡΟΜ
      ΔΙΑΒΑΣΕ_ΑΡΧΕΙΟ Α_ΠΟΣΟΤΗΤΑ, ΠΟΣΟΤΗΤΑ
      ΔΙΑΒΑΣΕ_ΑΡΧΕΙΟ Α_ΟΡΙΟ, ΟΡΙΟ
      ΔΙΑΒΑΣΕ_ΑΡΧΕΙΟ Α_ΑΞΙΑ, ΑΞΙΑ
      ΑΝ  ΟΧΙ (ΜΟΝΟ_ΟΡΙΟ ΚΑΙ(ΠΟΣΟΤΗΤΑ>ΟΡΙΟ)) ΤΟΤΕ
        ΤΕΛΙΚΗ_ΑΞΙΑ <-- ΑΞΙΑ*ΠΟΣΟΤΗΤΑ
        ΓΡΑΨΕ_ ΠΕΔΙΟ(ΜΕΡΟΣ(ΚΩΔΙΚΟΣ,1,6),10),ΠΕΔΙΟ('|'+ΕΙΔΟΣ,15),'|'
        ΓΡΑΨΕ ΠΟΣΟΤΗΤΑ:10:3,ΜΟΝΑΔΕΣ,'|',ΤΕΛΙΚΗ_ΑΞΙΑ:10:2,'|',ΟΡΙΟ:10:2,ΠΕΔΙΟ('|'+ΚΩΔ_ΠΡΟΜ,15)
      ΤΕΛΟΣ_ΑΝ
    ΤΕΛΟΣ_ΕΠΑΝΑΛΗΨΗΣ

  ΤΕΛΟΣ_ΑΝ

  ΚΛΕΙΣΕ_ΑΡΧΕΙΟ Α_ΕΙΔΟΣ
  ΚΛΕΙΣΕ_ΑΡΧΕΙΟ Α_ΚΩΔΙΚΟΣ
  ΚΛΕΙΣΕ_ΑΡΧΕΙΟ Α_ΜΟΝΑΔΕΣ
  ΚΛΕΙΣΕ_ΑΡΧΕΙΟ Α_ΚΩΔ_ΠΡΟΜ
  ΚΛΕΙΣΕ_ΑΡΧΕΙΟ Α_ΠΟΣΟΤΗΤΑ
  ΚΛΕΙΣΕ_ΑΡΧΕΙΟ Α_ΟΡΙΟ
  ΚΛΕΙΣΕ_ΑΡΧΕΙΟ Α_ΑΞΙΑ

ΤΕΛΟΣ_ΔΙΑΔΙΚΑΣΙΑΣ



ΣΥΝΑΡΤΗΣΗ ΤΑΞΙΝΟΜΗΣΗ (ΑΡΧΕΙΟΥ_ΟΝΟΜΑ, ΑΡΧΕΙΟΥ_ΕΠΙΘΕΜΑ):ΛΟΓΙΚΗ
ΜΕΤΑΒΛΗΤΕΣ
  ΑΚΕΡΑΙΕΣ: ΚΟΜΜΑΤΙΑ, ΣΕ_ΣΕΙΡΑ
  ΧΑΡΑΚΤΗΡΕΣ: ΑΡΧΕΙΟΥ_ΟΝΟΜΑ, ΑΡΧΕΙΟΥ_ΕΠΙΘΕΜΑ, ΠΡΟΗΓΟΥΜΕΝΟ, ΤΩΡΙΝΟ, Ν1, Ν2
  ΛΟΓΙΚΕΣ: ΟΚ
  ΑΡΧΕΙΑ ΧΑΡΑΚΤΗΡΩΝ: ΑΡΧΙΚΟ, ΝΟ1, ΝΟ2
ΑΡΧΗ

  ΣΥΣΧΕΤΙΣΕ_ΑΡΧΕΙΟ ΑΡΧΙΚΟ, ΑΡΧΕΙΟΥ_ΟΝΟΜΑ+'.'+ΑΡΧΕΙΟΥ_ΕΠΙΘΕΜΑ
  !ΑΝ ΥΠΑΡΧΕΙ_ΑΡΧΕΙΟ(ΑΡΧΕΙΟΥ_ΟΝΟΜΑ+'.'+ΑΡΧΕΙΟΥ_ΕΠΙΘΕΜΑ) ΤΟΤΕ
  ΑΝΟΙΞΕ_ΑΡΧΕΙΟ ΑΡΧΙΚΟ
  ΑΝ ΜΕΓΕΘΟΣ_ΑΡΧΕΙΟΥ(ΑΡΧΙΚΟ)=0 ΤΟΤΕ
    ΚΛΕΙΣΕ_ΑΡΧΕΙΟ ΑΡΧΙΚΟ
    ΤΑΞΙΝΟΜΗΣΗ <-- ΨΕΥΔΗΣ
  ΑΛΛΙΩΣ
    ΣΥΣΧΕΤΙΣΕ_ΑΡΧΕΙΟ ΝΟ1, ΑΡΧΕΙΟΥ_ΟΝΟΜΑ+'.1'
    ΔΗΜΙΟΥΡΓΗΣΕ_ΑΡΧΕΙΟ ΝΟ1
    ΣΥΣΧΕΤΙΣΕ_ΑΡΧΕΙΟ ΝΟ2, ΑΡΧΕΙΟΥ_ΟΝΟΜΑ+'.2'
    ΔΗΜΙΟΥΡΓΗΣΕ_ΑΡΧΕΙΟ ΝΟ2

    ΑΡΧΗ_ΕΠΑΝΑΛΗΨΗΣ
  ! ΦΑΣΗ Α
      ΠΡΟΗΓΟΥΜΕΝΟ <-- ''
      ΚΛΕΙΣΕ_ΑΡΧΕΙΟ ΝΟ1
      ΚΛΕΙΣΕ_ΑΡΧΕΙΟ ΝΟ2
      ΔΙΑΓΡΑΨΕ_ΑΡΧΕΙΟ ΝΟ1
      ΔΙΑΓΡΑΨΕ_ΑΡΧΕΙΟ ΝΟ2
      ΔΗΜΙΟΥΡΓΗΣΕ_ΑΡΧΕΙΟ ΝΟ1
      ΔΗΜΙΟΥΡΓΗΣΕ_ΑΡΧΕΙΟ ΝΟ2
      ΚΟΜΜΑΤΙΑ <-- 0
      ΣΕ_ΣΕΙΡΑ <-- 0
      ΔΙΕΤΡΕΞΕ_ΑΡΧΕΙΟ ΑΡΧΙΚΟ, 1
      ΟΣΟ ΟΧΙ ΤΕΛΟΣ_ΑΡΧΕΙΟΥ(ΑΡΧΙΚΟ) ΕΠΑΝΑΛΑΒΕ
        ΚΟΜΜΑΤΙΑ <-- ΚΟΜΜΑΤΙΑ+1
        ΔΙΑΒΑΣΕ_ΑΡΧΕΙΟ ΑΡΧΙΚΟ, ΤΩΡΙΝΟ
        ΑΝ ΤΩΡΙΝΟ>ΠΡΟΗΓΟΥΜΕΝΟ ΤΟΤΕ
          ΓΡΑΨΕ_ΑΡΧΕΙΟ ΝΟ1, ΤΩΡΙΝΟ
          ΣΕ_ΣΕΙΡΑ <-- ΣΕ_ΣΕΙΡΑ+1
        ΑΛΛΙΩΣ
          ΓΡΑΨΕ_ΑΡΧΕΙΟ ΝΟ2, ΤΩΡΙΝΟ
        ΤΕΛΟΣ_ΑΝ
        ΠΡΟΗΓΟΥΜΕΝΟ <-- ΤΩΡΙΝΟ
      ΤΕΛΟΣ_ΕΠΑΝΑΛΗΨΗΣ
  ! ΦΑΣΗ Β
      ΔΙΕΤΡΕΞΕ_ΑΡΧΕΙΟ ΑΡΧΙΚΟ, 1
      ΑΝ ΣΕ_ΣΕΙΡΑ<ΚΟΜΜΑΤΙΑ ΤΟΤΕ
        ΔΙΕΤΡΕΞΕ_ΑΡΧΕΙΟ ΝΟ1, 1
        ΔΙΑΒΑΣΕ_ΑΡΧΕΙΟ ΝΟ1, Ν1
        ΔΙΕΤΡΕΞΕ_ΑΡΧΕΙΟ ΝΟ2, 1
        ΔΙΑΒΑΣΕ_ΑΡΧΕΙΟ ΝΟ2, Ν2
        ΑΡΧΗ_ΕΠΑΝΑΛΗΨΗΣ
          ΟΣΟ (Ν1<=Ν2) ΚΑΙ (ΟΧΙ ΤΕΛΟΣ_ΑΡΧΕΙΟΥ(ΝΟ1)) ΕΠΑΝΑΛΑΒΕ
            ΓΡΑΨΕ_ΑΡΧΕΙΟ ΑΡΧΙΚΟ, Ν1
            ΔΙΑΒΑΣΕ_ΑΡΧΕΙΟ ΝΟ1, Ν1
          ΤΕΛΟΣ_ΕΠΑΝΑΛΗΨΗΣ
          ΟΣΟ (Ν2<Ν1) ΚΑΙ (ΟΧΙ ΤΕΛΟΣ_ΑΡΧΕΙΟΥ(ΝΟ2)) ΕΠΑΝΑΛΑΒΕ
            ΓΡΑΨΕ_ΑΡΧΕΙΟ ΑΡΧΙΚΟ, Ν2
            ΔΙΑΒΑΣΕ_ΑΡΧΕΙΟ ΝΟ2, Ν2
          ΤΕΛΟΣ_ΕΠΑΝΑΛΗΨΗΣ
        ΜΕΧΡΙΣ_ΟΤΟΥ ΤΕΛΟΣ_ΑΡΧΕΙΟΥ(ΝΟ1) Ή ΤΕΛΟΣ_ΑΡΧΕΙΟΥ(ΝΟ2)
        ΑΝ Ν2<Ν1 ΤΟΤΕ
          ΓΡΑΨΕ_ΑΡΧΕΙΟ ΑΡΧΙΚΟ, Ν2
          ΓΡΑΨΕ_ΑΡΧΕΙΟ ΑΡΧΙΚΟ, Ν1
        ΑΛΛΙΩΣ
          ΓΡΑΨΕ_ΑΡΧΕΙΟ ΑΡΧΙΚΟ, Ν1
          ΓΡΑΨΕ_ΑΡΧΕΙΟ ΑΡΧΙΚΟ, Ν2
        ΤΕΛΟΣ_ΑΝ
      ΤΕΛΟΣ_ΑΝ
      ΟΣΟ ΟΧΙ ΤΕΛΟΣ_ΑΡΧΕΙΟΥ(ΝΟ1) ΕΠΑΝΑΛΑΒΕ
        ΔΙΑΒΑΣΕ_ΑΡΧΕΙΟ ΝΟ1, Ν1
        ΓΡΑΨΕ_ΑΡΧΕΙΟ ΑΡΧΙΚΟ, Ν1
      ΤΕΛΟΣ_ΕΠΑΝΑΛΗΨΗΣ
      ΟΣΟ ΟΧΙ ΤΕΛΟΣ_ΑΡΧΕΙΟΥ(ΝΟ2) ΕΠΑΝΑΛΑΒΕ
        ΔΙΑΒΑΣΕ_ΑΡΧΕΙΟ ΝΟ2, Ν2
        ΓΡΑΨΕ_ΑΡΧΕΙΟ ΑΡΧΙΚΟ, Ν2
      ΤΕΛΟΣ_ΕΠΑΝΑΛΗΨΗΣ
      ΓΡΑΨΕ 'ΠΡΟΟΔΟΣ ',(ΣΕ_ΣΕΙΡΑ/ΚΟΜΜΑΤΙΑ)*100:10:0,' %'
    ΜΕΧΡΙΣ_ΟΤΟΥ ΚΟΜΜΑΤΙΑ=ΣΕ_ΣΕΙΡΑ
    ΚΛΕΙΣΕ_ΑΡΧΕΙΟ ΑΡΧΙΚΟ
    ΚΛΕΙΣΕ_ΑΡΧΕΙΟ ΝΟ1
    ΚΛΕΙΣΕ_ΑΡΧΕΙΟ ΝΟ2
    ΔΙΑΓΡΑΨΕ_ΑΡΧΕΙΟ ΝΟ1
    ΔΙΑΓΡΑΨΕ_ΑΡΧΕΙΟ ΝΟ2
    ΤΑΞΙΝΟΜΗΣΗ <-- ΑΛΗΘΗΣ
  ΤΕΛΟΣ_ΑΝ
  !ΑΛΛΙΩΣ
  ! ΤΑΞΙΝΟΜΗΣΗ <-- ΨΕΥΔΗΣ
  !ΤΕΛΟΣ_ΑΝ
ΤΕΛΟΣ_ΣΥΝΑΡΤΗΣΗΣ

 

_________________
Γλώσσα προγραμματισμού M2000


Κορυφή
 Προφίλ  
Απάντηση με παράθεση  
Τελευταίες δημοσιεύσεις:  Ταξινόμηση ανά  
Δημιουργία νέου θέματος Απαντήστε στο θέμα  [ 1 Δημοσίευση ] 

Όλοι οι χρόνοι είναι UTC + 2 ώρες [ DST ]


Μέλη σε σύνδεση

Μέλη σε αυτή την Δ. Συζήτηση: Δεν υπάρχουν εγγεγραμμένα μέλη και 7 επισκέπτες


Δεν μπορείτε να δημοσιεύετε νέα θέματα σε αυτή τη Δ. Συζήτηση
Δεν μπορείτε να απαντάτε σε θέματα σε αυτή τη Δ. Συζήτηση
Δεν μπορείτε να επεξεργάζεστε τις δημοσιεύσεις σας σε αυτή τη Δ. Συζήτηση
Δεν μπορείτε να διαγράφετε τις δημοσιεύσεις σας σε αυτή τη Δ. Συζήτηση
Δεν μπορείτε να επισυνάπτετε αρχεία σε αυτή τη Δ. Συζήτηση

Αναζήτηση για:
Μετάβαση σε:  
cron
Προβολές: