Τώρα είναι Πέμ 28 Μαρ 2024 01:25 pm

Όλοι οι χρόνοι είναι UTC + 2 ώρες [ DST ]




Δημιουργία νέου θέματος Απαντήστε στο θέμα  [ 1 Δημοσίευση ] 
Συγγραφέας Μήνυμα
 Θέμα δημοσίευσης: Εσπερινό - Θέμα 4
ΔημοσίευσηΔημοσιεύτηκε: Πέμ 12 Απρ 2007 04:22 pm 
Χωρίς σύνδεση

Εγγραφή: Κυρ 12 Οκτ 2003 01:52 am
Δημοσιεύσεις: 189
Τοποθεσία: ΝΙΚΑΙΑ - ΠΕΙΡΑΙΑΣ
Syntax: [ Download ] [ Hide ]
! ===============================================================================================

ΠΡΟΓΡΑΜΜΑ ΕΣ_2005_06_4
ΜΕΤΑΒΛΗΤΕΣ
  ΑΚΕΡΑΙΕΣ : b[20,20] , sum[20] , i , j , k , x , temp1
  ΧΑΡΑΚΤΗΡΕΣ : a[20] , temp2
ΑΡΧΗ
  ΓΙΑ i ΑΠΟ 1 ΜΕΧΡΙ 20
    ΓΡΑΨΕ 'Δώσε το όνομα του σχολείου Νο :' , i
    ΔΙΑΒΑΣΕ a[i]
  ΤΕΛΟΣ_ΕΠΑΝΑΛΗΨΗΣ

  ΓΙΑ i ΑΠΟ 1 ΜΕΧΡΙ 20
    ΓΙΑ j ΑΠΟ 1 ΜΕΧΡΙ 20
      b[i,j] <-- 0
    ΤΕΛΟΣ_ΕΠΑΝΑΛΗΨΗΣ
  ΤΕΛΟΣ_ΕΠΑΝΑΛΗΨΗΣ

  ΓΙΑ i ΑΠΟ 1 ΜΕΧΡΙ 20
    ΓΙΑ k ΑΠΟ 1 ΜΕΧΡΙ 5
      ΓΡΑΨΕ 'Σχολείο ', a[i] , 'ποιο σχολείο βαθμολογείς ;'
      ΔΙΑΒΑΣΕ j
      ΟΣΟ j = i ΕΠΑΝΑΛΑΒΕ
        ΓΡΑΨΕ 'Δε μπορείς να βαθμολογήσεις τον εαυτό σου. Ξαναδώσε αριθμό σχολείου.'
        ΔΙΑΒΑΣΕ j
      ΤΕΛΟΣ_ΕΠΑΝΑΛΗΨΗΣ

! Θα έπρεπε να γίνεται και έλεγχος, ώστε να μη βαθμολογηθεί το ίδιο σχολείο δύο φορές,
! αλλά αφού δεν το αναφέρει η άσκηση κρίνεται εξεζητημένο και δε γίνεται.
! Αν το ζητούσε θα έπρεπε να φτιάξουμε πίνακα x[5] με τους αριθμούς των σχολείου που
! αξιολογούνται και όταν δίνεται ο αριθμός του σχολείου να ελέγχουμε τις προηγούμενες
! θέσεις του πίνακα x ώστε να εξασφαλίζεται ότι δεν έχει ξαναδοθεί.
! Θα μπορούσαμε ακόμα να γεμίσουμε αρχικά τον πίνακα με τις βαθμολογίες και πριν εισάγουμε
! τη βαθμολογία σε αυτό να ελέγχουμε αν έχει περιεχόμενο το μηδέν ή όχι.

      ΓΡΑΨΕ 'και τί βαθμό δίνεις ;'
      ΔΙΑΒΑΣΕ x
      ΟΣΟ x < 1 ΚΑΙ x > 10 ΕΠΑΝΑΛΑΒΕ
        ΓΡΑΨΕ 'Λάθος. Η βαθμολογία πρέπει να είναι από 1 έως και 10. Ξαναδώσε.'
        ΔΙΑΒΑΣΕ x
      ΤΕΛΟΣ_ΕΠΑΝΑΛΗΨΗΣ
      b[i,j] <-- b[i,j] + x
    ΤΕΛΟΣ_ΕΠΑΝΑΛΗΨΗΣ
  ΤΕΛΟΣ_ΕΠΑΝΑΛΗΨΗΣ

  ΓΙΑ j ΑΠΟ 1 ΜΕΧΡΙ 20
    sum[j] <-- 0
    ΓΙΑ i ΑΠΟ 1 ΜΕΧΡΙ 20
      sum[j] <-- sum[j] + b[i,j]
    ΤΕΛΟΣ_ΕΠΑΝΑΛΗΨΗΣ
  ΤΕΛΟΣ_ΕΠΑΝΑΛΗΨΗΣ

  ΓΙΑ i ΑΠΟ 2 ΜΕΧΡΙ 20
    ΓΙΑ j ΑΠΟ 20 ΜΕΧΡΙ i ΜΕ ΒΗΜΑ -1
      ΑΝ sum[j-1] < sum[j] ΤΟΤΕ
        temp1 <-- sum[j-1]
        sum[j-1] <-- sum[j]
        sum[j] <-- temp1
        temp2 <-- a[j-1]
        a[j-1] <-- a[j]
        a[j] <-- temp2
      ΤΕΛΟΣ_ΑΝ
    ΤΕΛΟΣ_ΕΠΑΝΑΛΗΨΗΣ
  ΤΕΛΟΣ_ΕΠΑΝΑΛΗΨΗΣ

  ΓΡΑΨΕ 'ΑΠΟΤΕΛΕΣΜΑΤΑ ΣΧΟΛΙΚΟΥ ΔΙΑΓΩΝΙΣΜΟΥ'
  ΓΡΑΨΕ '================================='

  ΓΙΑ i ΑΠΟ 1 ΜΕΧΡΙ 20
    ΓΡΑΨΕ i , 'o ΣΧΟΛΕΙΟ είναι το', a[i] , 'με συνολική βαθμολογία' , sum[i]
  ΤΕΛΟΣ_ΕΠΑΝΑΛΗΨΗΣ

ΤΕΛΟΣ_ΠΡΟΓΡΑΜΜΑΤΟΣ
 


Κορυφή
 Προφίλ  
Απάντηση με παράθεση  
Τελευταίες δημοσιεύσεις:  Ταξινόμηση ανά  
Δημιουργία νέου θέματος Απαντήστε στο θέμα  [ 1 Δημοσίευση ] 

Όλοι οι χρόνοι είναι UTC + 2 ώρες [ DST ]


Μέλη σε σύνδεση

Μέλη σε αυτή την Δ. Συζήτηση : Δεν υπάρχουν εγγεγραμμένα μέλη και 1 επισκέπτης


Δεν μπορείτε να δημοσιεύετε νέα θέματα σε αυτή τη Δ. Συζήτηση
Δεν μπορείτε να απαντάτε σε θέματα σε αυτή τη Δ. Συζήτηση
Δεν μπορείτε να επεξεργάζεστε τις δημοσιεύσεις σας σε αυτή τη Δ. Συζήτηση
Δεν μπορείτε να διαγράφετε τις δημοσιεύσεις σας σε αυτή τη Δ. Συζήτηση
Δεν μπορείτε να επισυνάπτετε αρχεία σε αυτή τη Δ. Συζήτηση

Αναζήτηση για:
Μετάβαση σε:  
cron
Προβολές: