Τώρα είναι Πέμ 28 Μαρ 2024 06:50 pm

Όλοι οι χρόνοι είναι UTC + 2 ώρες [ DST ]




Δημιουργία νέου θέματος Απαντήστε στο θέμα  [ 4 Δημοσιεύσεις ] 
Συγγραφέας Μήνυμα
 Θέμα δημοσίευσης: Αγγλοελληνικό Λεξικό !!!
ΔημοσίευσηΔημοσιεύτηκε: Τετ 28 Νοέμ 2007 04:16 pm 
Χωρίς σύνδεση

Εγγραφή: Τετ 28 Νοέμ 2007 03:41 pm
Δημοσιεύσεις: 2
Τοποθεσία: Ρόδος
Στην παρακάτω άσκηση δημιουργείται ένα λεξικό ελληνικών και αγγλικών λέξεων. Η παρακάτω άσκηση χρησιμοποιεί δύο μονοδιάστατους πίνακες, και θεωρείται ότι έιναι άδειο στην αρχή (Αφού δεν διδάσκεται η ανάγνωση από Ι/Ο συσκευές - κακώς κατά την γνώμη μου).
Χρησιμοποιεί κυρίως μια συνάρτηση για αναζήτηση στους πίνακες των λέξεων. Στη συνάρτηση αυτή στελνουμε τον πίνακα που ζητάμε να κάνουμε αναζήτηση, το τρέχον δείκτη λέξεων(μέχρι ποιο περιεχόμενο έχει λέξεις) καθώς και την λέξη αναζήτησης, ενώ η συνάρτηση επιστρέφει 0 αν δεν βρήκε την λέξη ή τον δείκτη της λέξης που βρήκε.
Επίσης το πρόγραμμα ελέγχει: 1) αν το λεξικό είναι άδειο, 2) αν είναι γεμάτο, 3) αν έχει εισαγθεί ξανά μια λέξη, για την αποφυγή της διπλής εισαγωγής λέξης (Θεωρούμε ότι μια λέξη έχει μόνο μια αντιστοίχιση από Ελληνικά στα Αγγλικά). :)

Syntax: [ Download ] [ Hide ]

ΠΡΟΓΡΑΜΜΑ ΛΕΞΙΚΟ

ΜΕΤΑΒΛΗΤΕΣ
  ΑΚΕΡΑΙΕΣ: Ι,Κ,Χ
  ΧΑΡΑΚΤΗΡΕΣ: ΕΛΛΗΝΙΚΑ[100],ΑΓΓΛΙΚΑ[100]

ΑΡΧΗ                      
  Ι <-- 0

  ΑΡΧΗ_ΕΠΑΝΑΛΗΨΗΣ
    ΑΡΧΗ_ΕΠΑΝΑΛΗΨΗΣ
      ΓΡΑΨΕ 'ΑΓΓΛΟΕΛΛΗΝΙΚΟ ΛΕΞΙΚΟ'
      ΓΡΑΨΕ 'ΕΙΣΑΓΕ ΤΗΝ ΕΠΙΛΟΓΗ ΣΟΥ'
      ΓΡΑΨΕ '1. ΜΕΤΑΦΡΑΣΗ ΑΠΟ ΑΓΓΛΙΚΑ ΣΤΑ ΕΛΛΗΝΙΚΑ'
      ΓΡΑΨΕ '2. ΜΕΤΑΦΡΑΣΗ ΑΠΟ ΕΛΛΗΝΙΚΑ ΣΤΑ ΑΓΓΛΙΚΑ'
      ΓΡΑΨΕ '3. ΕΙΣΑΓΩΓΗ ΝΕΑΣ ΛΕΞΗΣ'
      ΓΡΑΨΕ '4. ΕΞΟΔΟΣ ΑΠΟ ΤΟ ΠΡΟΓΡΑΜΜΑ'
      ΔΙΑΒΑΣΕ Χ
    ΜΕΧΡΙΣ_ΟΤΟΥ (Χ>=1) ΚΑΙ (Χ<=4)
    ΑΝ (Χ=1) ΤΟΤΕ
      ΑΝ (Ι=0) ΤΟΤΕ
        ΓΡΑΨΕ ' ΣΥΓΓΝΩΜΗ ΤΟ ΛΕΞΙΚΟ ΕΙΝΑΙ ΑΔΕΙΟ...'
      ΑΛΛΙΩΣ
        ΓΡΑΨΕ 'ΔΩΣΕ ΤΗ ΛΕΞΗ ΣΤΗΝ ΑΓΓΛΙΚΗ'
        ΔΙΑΒΑΣΕ Ψ
        Κ <-- Φ(ΑΓΓΛΙΚΑ,Ι,Ψ)
        ΑΝ (Κ=0) ΤΟΤΕ
          ΓΡΑΨΕ 'Η ΛΕΞΗ ',Ψ,' ΔΕΝ ΥΠΑΡΧΕΙ ΣΤΟ ΛΕΞΙΚΟ.'
        ΑΛΛΙΩΣ
          ΓΡΑΨΕ 'Η ΛΕΞΗ ',ΑΓΓΛΙΚΑ[Κ],' ΣΗΜΑΙΝΕΙ: ',ΕΛΛΗΝΙΚΑ[Κ]
        ΤΕΛΟΣ_ΑΝ
      ΤΕΛΟΣ_ΑΝ
    ΑΛΛΙΩΣ_ΑΝ (Χ=2) ΤΟΤΕ
      ΑΝ (Ι=0) ΤΟΤΕ
        ΓΡΑΨΕ ' ΣΥΓΓΝΩΜΗ ΤΟ ΛΕΞΙΚΟ ΕΙΝΑΙ ΑΔΕΙΟ...'
      ΑΛΛΙΩΣ
        ΓΡΑΨΕ 'ΔΩΣΕ ΤΗ ΛΕΞΗ ΣΤΗΝ ΕΛΛΗΝΙΚΗ'
        ΔΙΑΒΑΣΕ Ψ
        Κ <-- Φ(ΕΛΛΗΝΙΚΑ,Ι,Ψ)
        ΑΝ (Κ=0) ΤΟΤΕ
          ΓΡΑΨΕ 'Η ΛΕΞΗ ',Ψ,' ΔΕΝ ΥΠΑΡΧΕΙ ΣΤΟ ΛΕΞΙΚΟ.'
        ΑΛΛΙΩΣ
          ΓΡΑΨΕ 'Η ΛΕΞΗ ',ΕΛΛΗΝΙΚΑ[Κ],' ΣΗΜΑΙΝΕΙ: ',ΑΓΓΛΙΚΑ[Κ]
        ΤΕΛΟΣ_ΑΝ
      ΤΕΛΟΣ_ΑΝ
    ΑΛΛΙΩΣ_ΑΝ (Χ=3) ΤΟΤΕ
      ΑΝ (Ι=100) ΤΟΤΕ
        ΓΡΑΨΕ 'ΤΟ ΛΕΞΙΚΟ ΕΙΝΑΙ ΓΕΜΑΤΟ'
      ΑΛΛΙΩΣ
        ΓΡΑΨΕ 'ΕΙΣΑΓΕ ΤΗΝ ΛΕΞΗ ΣΤΑ ΕΛΛΗΝΙΚΑ'
        ΔΙΑΒΑΣΕ Ψ
        Κ <-- Φ(ΕΛΛΗΝΙΚΑ,Ι,Ψ)
        ΑΝ (Κ<>0) ΤΟΤΕ
          ΓΡΑΨΕ 'Η ΛΕΞΗ ',Ψ,' ΥΠΑΡΧΕΙ ΞΑΝΑ ΣΤΟ ΛΕΞΙΚΟ!!!! '
        ΑΛΛΙΩΣ
          Ι <-- Ι+1
          ΕΛΛΗΝΙΚΑ[Ι] <-- Ψ
          ΓΡΑΨΕ 'ΕΙΣΑΓΕ ΤΗΝ ΛΕΞΗ ΣΤΑ ΑΓΓΛΙΚΑ'
          ΔΙΑΒΑΣΕ Ψ
          Κ <-- Φ(ΑΓΓΛΙΚΑ,Ι-1,Ψ)
          ΑΝ (Κ<>0) ΤΟΤΕ
            ΓΡΑΨΕ 'Η ΛΕΞΗ ',Ψ,' ΥΠΑΡΧΕΙ ΞΑΝΑ ΣΤΟ ΛΕΞΙΚΟ!!!! '
            ΓΡΑΨΕ 'ΛΥΠΑΜΑΙ Η ΛΕΞΗ ',ΕΛΛΗΝΙΚΑ[Ι],' ΥΠΑΡΧΕΙ ΞΑΝΑ ΣΤΟ ΛΕΞΙΚΟ, ΚΑΙ ΘΑ ΑΚΥΡΩΘΕΙ.'
            Ι <-- Ι-1
          ΑΛΛΙΩΣ
            ΑΓΓΛΙΚΑ[Ι] <-- Ψ
          ΤΕΛΟΣ_ΑΝ
        ΤΕΛΟΣ_ΑΝ
      ΤΕΛΟΣ_ΑΝ
    ΑΛΛΙΩΣ
      ΓΡΑΨΕ 'ΕΥΧΑΡΙΣΤΟΥΜΕ. ΑΝΤΙΟ...'
    ΤΕΛΟΣ_ΑΝ
  ΜΕΧΡΙΣ_ΟΤΟΥ (Χ=4)
ΤΕΛΟΣ_ΠΡΟΓΡΑΜΜΑΤΟΣ

ΣΥΝΑΡΤΗΣΗ Φ(Π,Ι,Ψ):ΑΚΕΡΑΙΑ

ΜΕΤΑΒΛΗΤΕΣ
  ΧΑΡΑΚΤΗΡΕΣ: Π[100]
  ΑΚΕΡΑΙΕΣ: Ι,Κ,ΘΕΣΗ
  ΛΟΓΙΚΕΣ: ΣΗΜΑΙΑ
ΑΡΧΗ
  ΣΗΜΑΙΑ <-- ΨΕΥΔΗΣ
  Κ <-- 1
  ΘΕΣΗ <-- 1
  ΟΣΟ (Κ<=Ι) ΚΑΙ (ΣΗΜΑΙΑ=ΨΕΥΔΗΣ) ΕΠΑΝΑΛΑΒΕ
    ΑΝ (Π[Κ]=Ψ) ΤΟΤΕ
      ΣΗΜΑΙΑ <-- ΑΛΗΘΗΣ
      ΘΕΣΗ <-- Κ
    ΑΛΛΙΩΣ
      Κ <-- Κ+1
    ΤΕΛΟΣ_ΑΝ
  ΤΕΛΟΣ_ΕΠΑΝΑΛΗΨΗΣ
  ΑΝ ( ΣΗΜΑΙΑ = ΑΛΗΘΗΣ ) ΤΟΤΕ
    Φ <-- ΘΕΣΗ
  ΑΛΛΙΩΣ
    Φ <-- 0
  ΤΕΛΟΣ_ΑΝ
ΤΕΛΟΣ_ΣΥΝΑΡΤΗΣΗΣ
 

_________________
Με χαρά να απαντήσω σε όλες τις απορίες!


Κορυφή
 Προφίλ  
Απάντηση με παράθεση  
 Θέμα δημοσίευσης: Re: Αγγλοελληνικό Λεξικό !!!
ΔημοσίευσηΔημοσιεύτηκε: Παρ 14 Αύγ 2009 08:29 pm 
Χωρίς σύνδεση

Εγγραφή: Παρ 14 Αύγ 2009 08:17 pm
Δημοσιεύσεις: 2
Το δοκίμασα πολύ καλό. Μου είναι χρήσιμο γιατί θέλω να κάνω κι εγώ ένα λεξικό αλλά πέραν της γλωσσομάθειας δεν σκαμπάζω τίποτα από προγραμματισμό (μονάχα λίγη Pascal). Παρατήρησα όμως το εξής ότι όταν κλείσεις το πρόγραμμα και μετά το ξανανοίξεις δεν κρατάει τις λέξεις που έχει εισάγει. Πως μπορώ να το φτιάξω αυτό;


Κορυφή
 Προφίλ  
Απάντηση με παράθεση  
 Θέμα δημοσίευσης: Re: Αγγλοελληνικό Λεξικό !!!
ΔημοσίευσηΔημοσιεύτηκε: Παρ 14 Αύγ 2009 10:51 pm 
Χωρίς σύνδεση

Εγγραφή: Τετ 28 Νοέμ 2007 03:41 pm
Δημοσιεύσεις: 2
Τοποθεσία: Ρόδος
prepei na dimiourgiseis arxeio leksewn sta ellinika agglika (p.x. kathe grammi mporei na periexei mia leksi sta ellinika, kai tis antistoixes lekseis sta agglika sthn epomeni grammi - i stin idia, meta apo ena opoiodipote eidiko xaraktira).
Kai apla anti na eisageis mia mia leksi sti leksiko, stin arxhi tou programmatos diabazeis to arxeio lekswn pou echeis dimiourgisei.

Twra an thes na deis stin pascal pws ginetai afto, kane anazitisi me lima: PASCAL FILE HANDLING

p.s.
O metaglwtistis ths glwssomatheias, nomizw oti echei epeksergasia archeiwn.

kali sinecheia.

_________________
Με χαρά να απαντήσω σε όλες τις απορίες!


Κορυφή
 Προφίλ  
Απάντηση με παράθεση  
 Θέμα δημοσίευσης: Re: Αγγλοελληνικό Λεξικό !!!
ΔημοσίευσηΔημοσιεύτηκε: Σάβ 15 Αύγ 2009 01:01 am 
Χωρίς σύνδεση

Εγγραφή: Παρ 14 Αύγ 2009 08:17 pm
Δημοσιεύσεις: 2
Γιάννης Φιλόπουλος έγραψε:
prepei na dimiourgiseis arxeio leksewn sta ellinika agglika (p.x. kathe grammi mporei na periexei mia leksi sta ellinika, kai tis antistoixes lekseis sta agglika sthn epomeni grammi - i stin idia, meta apo ena opoiodipote eidiko xaraktira).
Kai apla anti na eisageis mia mia leksi sti leksiko, stin arxhi tou programmatos diabazeis to arxeio lekswn pou echeis dimiourgisei.

Twra an thes na deis stin pascal pws ginetai afto, kane anazitisi me lima: PASCAL FILE HANDLING

p.s.
O metaglwtistis ths glwssomatheias, nomizw oti echei epeksergasia archeiwn.

kali sinecheia.

Συγνώμη αλλά επειδή είμαι πολύ αρχάριος δεν κατάλαβα πολύ καλά πως γίνεται θα μπορούσες να δώσεις ένα παράδειγμα κώδικα;

Υ.Γ.1 Ευχαριστώ εκ των προτέρων
Υ.Γ.2 Χρησιμοποιώ τον Μεταγλωττιστή


Κορυφή
 Προφίλ  
Απάντηση με παράθεση  
Τελευταίες δημοσιεύσεις:  Ταξινόμηση ανά  
Δημιουργία νέου θέματος Απαντήστε στο θέμα  [ 4 Δημοσιεύσεις ] 

Όλοι οι χρόνοι είναι UTC + 2 ώρες [ DST ]


Μέλη σε σύνδεση

Μέλη σε αυτή την Δ. Συζήτηση: Δεν υπάρχουν εγγεγραμμένα μέλη και 2 επισκέπτες


Δεν μπορείτε να δημοσιεύετε νέα θέματα σε αυτή τη Δ. Συζήτηση
Δεν μπορείτε να απαντάτε σε θέματα σε αυτή τη Δ. Συζήτηση
Δεν μπορείτε να επεξεργάζεστε τις δημοσιεύσεις σας σε αυτή τη Δ. Συζήτηση
Δεν μπορείτε να διαγράφετε τις δημοσιεύσεις σας σε αυτή τη Δ. Συζήτηση
Δεν μπορείτε να επισυνάπτετε αρχεία σε αυτή τη Δ. Συζήτηση

Αναζήτηση για:
Μετάβαση σε:  
cron
Προβολές: