Ασκησιολόγιο ΓλωσσοΜάθειας
http://www.spinet.gr/glossomatheia/programs/

Επαναληπτικές Εσπερινό - Θέμα 4
http://www.spinet.gr/glossomatheia/programs/viewtopic.php?f=30&t=656
Σελίδα 1 από 1

Συγγραφέας:  ΧΑΤΖΗΤΣΟΜΠΑΝΗΣ ΘΕΟΦΙΛΟΣ [ Πέμ 24 Ιούλ 2008 07:22 pm ]
Θέμα δημοσίευσης:  Επαναληπτικές Εσπερινό - Θέμα 4

Syntax: [ Download ] [ Hide ]
! ============= ΕΣΠΕΡΙΝΟ ΙΟΥΛΙΟΣ 2007 - Θέμα 4 ========================
!
! Σε ένα Μετεωρολογικό Σταθμό καταγράφονται ανά ημέρα και ώρα η
! θερμοκρασία του περιβάλλοντος για μία εβδομάδα.
! Να γράψετε αλγόριθμο που:
! α. Διαβάζει:
!    - τα ονόματα των επτά ημερών της εβδομάδας και τα καταχωρεί σε
!      μονοδιάστατο πίνακα.
!    - τη θερμοκρασία για κάθε ημέρα της εβδομάδας και κάθε ώρα της
!      ημέρας και την καταχωρεί σε δισδιάστατο πίνακα, ελέγχοντας οι
!      τιμές της θερμοκρασίας να είναι από -20 μέχρι και 50.
! β. Υπολογίζει για κάθε ημέρα τη μέση θερμοκρασία και την καταχωρεί
!    σε μονοδιάστατο πίνακα.
! γ. Βρίσκει και εμφανίζει τη μέγιστη μέση θερμοκρασία της εβδομάδας
!    από τον πίνακα των μέσων θερμοκρασιών.
! δ. Βρίσκει και εμφανίζει την ημέρα της εβδομάδας με τη μέγιστη μέση
!    θερμοκρασία (να θεωρήσετε ότι υπάρχει μόνο μία τέτοια ημέρα).
! ε. Υπολογίζει και εμφανίζει το πλήθος των ημερών της εβδομάδας που
!    είχαν μέση θερμοκρασία μεγαλύτερη των 200 C.
!
! =====================================================================

ΠΡΟΓΡΑΜΜΑ ESP_JUL_2007_04
ΜΕΤΑΒΛΗΤΕΣ
  ΑΚΕΡΑΙΕΣ: i , j  , n
  ΠΡΑΓΜΑΤΙΚΕΣ: θ[7,24] , μεση[7] , max , s
  ΧΑΡΑΚΤΗΡΕΣ: day[7] , top
ΑΡΧΗ
  ΓΙΑ i ΑΠΟ 1 ΜΕΧΡΙ 7
    ΓΡΑΨΕ 'Δώσε το όνομα της ' , i ,'ημέρας.'
    ΔΙΑΒΑΣΕ day[i]
  ΤΕΛΟΣ_ΕΠΑΝΑΛΗΨΗΣ

  ΓΙΑ i ΑΠΟ 1 ΜΕΧΡΙ 7
    ΓΙΑ j ΑΠΟ 1 ΜΕΧΡΙ 24
      ΓΡΑΨΕ 'Δώσε τη θερμοκρασία της' , day[i] ,'την ώρα' , j
      ΔΙΑΒΑΣΕ θ[i,j]
      ΟΣΟ θ[i,j] < -20 ή θ[i,j] > 50 ΕΠΑΝΑΛΑΒΕ
        ΓΡΑΨΕ 'Λάθος. Ξαναδώσε'
        ΔΙΑΒΑΣΕ θ[i,j]
      ΤΕΛΟΣ_ΕΠΑΝΑΛΗΨΗΣ
    ΤΕΛΟΣ_ΕΠΑΝΑΛΗΨΗΣ
  ΤΕΛΟΣ_ΕΠΑΝΑΛΗΨΗΣ

  ΓΙΑ i ΑΠΟ 1 ΜΕΧΡΙ 7
    s <-- 0
    ΓΙΑ j ΑΠΟ 1 ΜΕΧΡΙ 24
      s <-- s + θ[i,j]
    ΤΕΛΟΣ_ΕΠΑΝΑΛΗΨΗΣ
    μεση[i] <-- s/24
  ΤΕΛΟΣ_ΕΠΑΝΑΛΗΨΗΣ

  max <-- -21        ! Θα μπορούσε να μεί και μία από τις τιμές που ήδη έχουμε π.χ. max <-- μεση[1]
  ΓΙΑ i ΑΠΟ 1 ΜΕΧΡΙ 7
    ΑΝ μεση[i] > max ΤΟΤΕ
      max <-- μεση[i]
      top <-- day[i]
    ΤΕΛΟΣ_ΑΝ
  ΤΕΛΟΣ_ΕΠΑΝΑΛΗΨΗΣ
  ΓΡΑΨΕ 'Η μέρα με τη μέγιστη μέση θερμοκρασία ήταν για αυτήν την εβδομάδα' , top

  n <-- 0
  ΓΙΑ i ΑΠΟ 1 ΜΕΧΡΙ 7
    ΑΝ μεση[i] > 20 ΤΟΤΕ
      n <-- n + 1
    ΤΕΛΟΣ_ΑΝ
  ΤΕΛΟΣ_ΕΠΑΝΑΛΗΨΗΣ
  ΓΡΑΨΕ n , 'μέρες αυτή την εβδομάδα είχαμε θερμοκρασία πάνω από 20 βαθμούς.'

ΤΕΛΟΣ_ΠΡΟΓΡΑΜΜΑΤΟΣ
 

Σελίδα 1 από 1 Όλοι οι χρόνοι είναι UTC + 2 ώρες [ DST ]
Powered by phpBB® Forum Software © phpBB Group
http://www.phpbb.com/