Ασκησιολόγιο ΓλωσσοΜάθειας
https://www.spinet.gr/glossomatheia/programs/

Εσπερινό - Θέμα 4
https://www.spinet.gr/glossomatheia/programs/viewtopic.php?f=30&t=576
Σελίδα 1 από 1

Συγγραφέας:  ΧΑΤΖΗΤΣΟΜΠΑΝΗΣ ΘΕΟΦΙΛΟΣ [ Παρ 08 Ιουν 2007 12:58 pm ]
Θέμα δημοσίευσης:  Εσπερινό - Θέμα 4

Syntax: [ Download ] [ Hide ]
! ===============================================================================================
! ΕΣΠΕΡΙΝΟ - ΙΟΥΝΙΟΣ 2007 - ΘΕΜΑ 4
! ===============================================================================================
! Σε ένα πανεπιστημιακό τμήμα εισήχθησαν κατόπιν γενικών εξετάσεων 235 φοιτητές προερχόμενοι από
! την ΤΕΧΝΟΛΟΓΙΚΗ ή τη ΘΕΤΙΚΗ κατεύθυνση.
! Να αναπτύξετε αλγόριθμο, ο οποίος:
!  α. Για καθένα από τους 235 φοιτητές διαβάζει:
!     το ονοματεπώνυμο του,
!     τα μόρια εισαγωγής του,
!     την κατεύθυνση του, η οποία μπορεί να είναι "ΤΕΧΝΟΛΟΓΙΚΗ" ή "ΘΕΤΙΚΗ", ελέγχοντας την
!     εγκυρότητα εισαγωγής της και καταχωρίζει τα δεδομένα αυτά σε τρεις πίνακες.
!
!  β. Υπολογίζει και εμφανίζει:
!     1. το μέσο όρο των μορίων εισαγωγής των φοιτητών που προέρχονται από την ΤΕΧΝΟΛΟΓΙΚΗ
!        κατεύθυνση.
!     2. το ποσοστό των φοιτητών, που προέρχονται από την ΤΕΧΝΟΛΟΓΙΚΗ κατεύθυνση.
!     3. την κατεύθυνση, από την οποία προέρχεται ο φοιτητής με τα περισσότερα μόρια εισαγωγής
!        (να θεωρήσετε ότι δεν υπάρχει περίπτωση ισοβαθμίας).
!     4. τα ονοματεπώνυμα των φοιτητών που προέρχονται από την ΤΕΧΝΟΛΟΓΙΚΗ κατεύθυνση, για τους
!        οποίους τα μόρια εισαγωγής τους είναι περισσότερα από το μέσο όρο των μορίων εισαγωγής
!        των φοιτητών που προέρχονται από την ΤΕΧΝΟΛΟΓΙΚΗ κατεύθυνση.
! ===============================================================================================

ΠΡΟΓΡΑΜΜΑ  ES_2007_4
ΜΕΤΑΒΛΗΤΕΣ
  ΑΚΕΡΑΙΕΣ : μορια[235] , i , N , s , max
  ΠΡΑΓΜΑΤΙΚΕΣ : mo , pos
  ΧΑΡΑΚΤΗΡΕΣ : ονομ[235] , κατ[235] , x
ΑΡΧΗ
  ΓΙΑ i ΑΠΟ 1 ΜΕΧΡΙ 235
    ΓΡΑΨΕ 'Δώσε το ονοματεπώνυμο του/της', i
    ΔΙΑΒΑΣΕ ονομ[i]
    ΓΡΑΨΕ 'Με πόσα μόρια πέρασε ;'
    ΔΙΑΒΑΣΕ μορια[i]
    ΓΡΑΨΕ 'Από ποια κατεύθυνση;'
    ΔΙΑΒΑΣΕ κατ[i]
    ΟΣΟ κατ[i] <> 'ΤΕΧΝΟΛΟΓΙΚΗ' ΚΑΙ κατ[i] <> 'ΘΕΤΙΚΗ' ΕΠΑΝΑΛΑΒΕ
      ΓΡΑΨΕ 'Λάθος. Ξαναδώσε ΤΕΧΝΟΛΟΓΙΚΗ ή ΘΕΤΙΚΗ'
      ΔΙΑΒΑΣΕ κατ[i]            
    ΤΕΛΟΣ_ΕΠΑΝΑΛΗΨΗΣ
  ΤΕΛΟΣ_ΕΠΑΝΑΛΗΨΗΣ

  s <-- 0
  N <-- 0
  ΓΙΑ i ΑΠΟ 1 ΜΕΧΡΙ 235
    ΑΝ κατ[i] = 'ΤΕΧΝΟΛΟΓΙΚΗ' ΤΟΤΕ
      s <-- s + μορια[i]
      N <-- N + 1
    ΤΕΛΟΣ_ΑΝ
  ΤΕΛΟΣ_ΕΠΑΝΑΛΗΨΗΣ
  mo <-- s / N
  ΓΡΑΨΕ 'Ο μέσος όρος των μορίων εισαγωγής των φοιτητών που προέρχονται από την ΤΕΧΝΟΛΟΓΙΚΗ κατεύθυνση είναι' , mo

  pos <-- 100*N/235
  ΓΡΑΨΕ 'Το ποσοστό των φοιτητών που προέρχονται από την τεχνολογική κατεύθυνση είναι' , pos

  max <-- 0
  ΓΙΑ i ΑΠΟ 1 ΜΕΧΡΙ 235
    ΑΝ μορια[i] > max ΤΟΤΕ
      max <-- μορια[i]
      x <-- κατ[i]
    ΤΕΛΟΣ_ΑΝ
  ΤΕΛΟΣ_ΕΠΑΝΑΛΗΨΗΣ
  ΓΡΑΨΕ 'Ο φοιτητής με τα περισσότερα μόρια προέρχεται από την' , x , 'κατεύθυνση.'

  ΓΡΑΨΕ 'Οι φοιτητές της τεχνολογικής κατεύθυνσης με μόρια περισσότερα από το μέσο όρο είναι οι εξής'
  ΓΙΑ i ΑΠΟ 1 ΜΕΧΡΙ 235
    ΑΝ κατ[i] = 'ΤΕΧΝΟΛΟΓΙΚΗ' ΚΑΙ μορια[i] > mo ΤΟΤΕ
      ΓΡΑΨΕ ονομ[i]
    ΤΕΛΟΣ_ΑΝ
  ΤΕΛΟΣ_ΕΠΑΝΑΛΗΨΗΣ

ΤΕΛΟΣ_ΠΡΟΓΡΑΜΜΑΤΟΣ

Σελίδα 1 από 1 Όλοι οι χρόνοι είναι UTC + 2 ώρες [ DST ]
Powered by phpBB® Forum Software © phpBB Group
http://www.phpbb.com/