Τώρα είναι Δευτ 26 Αύγ 2019 08:44 am

Όλοι οι χρόνοι είναι UTC + 2 ώρες [ DST ]




Δημιουργία νέου θέματος Απαντήστε στο θέμα  [ 1 Δημοσίευση ] 
Συγγραφέας Μήνυμα
ΔημοσίευσηΔημοσιεύτηκε: Πέμ 12 Απρ 2007 03:53 pm 
Χωρίς σύνδεση

Εγγραφή: Κυρ 12 Οκτ 2003 01:52 am
Δημοσιεύσεις: 189
Τοποθεσία: ΝΙΚΑΙΑ - ΠΕΙΡΑΙΑΣ
Syntax: [ Download ] [ Hide ]
! ===============================================================================================
! ΗΜΕΡΗΣΙΟ - ΙΟΥΛΙΟΣ 2005 - ΘΕΜΑ 4
! ===============================================================================================
! Μια αεροπορική εταιρία ταξιδεύει σε 15 προορισμούς του εσωτερικού. Στα πλαίσια της οικονομικής
! πολιτικής που πρόκειται να εφαρμόσει, κατέγραψε το ποσοστό πληρότητας των πτήσεων για κάθε μήνα
! του προηγούμενου ημερολογιακού έτους. Η πολιτική έχει ως εξής :
!  -  Δε θα γίνει καμία περικοπή σε προορισμούς, στους οποίους το μέσο ετήσιο ποσοστό πληρότητας
!     των πτήσεων είναι μεγαλύτερο του 65.
!  -  Θα γίνουν περικοπές πτήσεων σε προορισμούς, στους οποίους το μέσο ετήσιο ποσοστό πληρότητας
!     των πτήσεων κυμαίνεται από 40 έως και 65. Οι περικοπές θα γίνουν μόνο σε εκείνους τους μήνες
!     που το ποσοστό πληρότητάς τους είναι μικρότερο του 40.
!  -  Θα καταργηθούν οι προορισμοί, στους οποίους το μέσο ετήσιο ποσοστό πληρότητας των πτήσεων
!     είναι μικρότερο του 40.
! Να γραφεί αλγόριθμος ο οποίος :
!  1. Να διαβάζει τα ονόματα των 15 προορισμών και να τα αποθηκεύει σε ένα μονοδιάστατο πίνακα.
!  2. Να διαβάζει τα ποσοστά πληρότητας των πτήσεων των 15 προορισμών για κάθε μήνα και να τα
!     αποθηκεύει σε δισδιάστατο πίνακα κάνοντας έλεγχο στην καταχώριση των δεδομένων, ώστε να
!     καταχωρούνται μόνο οι τιμές που είναι από 0 έως και 100.
!  3. Να βρίσκει και να τυπώνει τα ονόματα των προορισμών που δε θα γίνει καμία περικοπή πτήσεων.
!  4. Να βρίσκει και να τυπώνει τα ονόματα των προορισμών που θα καταργηθούν.
!  5. Να βρίσκει και να τυπώνει τα ονόματα των προορισμών, στους οποίους θα γίνουν περικοπές
!     πτήσεων, καθώς και τους μήνες (αύξοντα αριθμό μήνα) που θα γίνουν οι περικοπές.
! ===============================================================================================

ΠΡΟΓΡΑΜΜΑ ΗΜ_2005_07_4
ΜΕΤΑΒΛΗΤΕΣ
  ΑΚΕΡΑΙΕΣ : i , j
  ΠΡΑΓΜΑΤΙΚΕΣ : p[15,12] , mo[15] , s
  ΧΑΡΑΚΤΗΡΕΣ : a[15]
ΑΡΧΗ
  ΓΙΑ i ΑΠΟ 1 ΜΕΧΡΙ 15
    ΓΡΑΨΕ 'Δώσε το όνομα του προορισμού' , i
    ΔΙΑΒΑΣΕ a[i]
    ΓΡΑΨΕ 'Δώσε το πσοσοτό πληρότητάς του για κάθε έναν από τους μήνες του έτους.'
    ΓΙΑ j ΑΠΟ 1 ΜΕΧΡΙ 12
      ΓΡΑΨΕ j , 'ος ΜΗΝΑΣ = ;'
      ΔΙΑΒΑΣΕ p[i,j]
      ΟΣΟ p[i,j] < 0 ή p[i,j] > 100 ΕΠΑΝΑΛΑΒΕ
        ΓΡΑΨΕ 'Λάθος. Ξαναδώσε.'
        ΔΙΑΒΑΣΕ p[i,j]
      ΤΕΛΟΣ_ΕΠΑΝΑΛΗΨΗΣ
    ΤΕΛΟΣ_ΕΠΑΝΑΛΗΨΗΣ
  ΤΕΛΟΣ_ΕΠΑΝΑΛΗΨΗΣ

! ΥΠΟΛΟΓΙΣΜΟΣ ΜΕΣΟΥ ΕΤΗΣΙΟΥ ΠΟΣΟΣΤΟΥ ΠΛΗΡΟΤΗΤΑΣ
  ΓΙΑ i ΑΠΟ 1 ΜΕΧΡΙ 15
    s <-- 0
    ΓΙΑ j ΑΠΟ 1 ΜΕΧΡΙ 12
      s <-- s + p[i,j]
    ΤΕΛΟΣ_ΕΠΑΝΑΛΗΨΗΣ
    mo[i] <-- s / 12
  ΤΕΛΟΣ_ΕΠΑΝΑΛΗΨΗΣ

! ΠΡΟΟΡΙΣΜΟΙ ΧΩΡΙΣ ΚΑΜΜΙΑ ΠΕΡΙΚΟΠΗ
  ΓΡΑΨΕ 'Δε θα γίνει καμμία περικοπή στις πτήσεις προς τους ακόλουθους προορισμούς.'
  ΓΙΑ i ΑΠΟ 1 ΜΕΧΡΙ 15
    ΑΝ mo[i] > 65 ΤΟΤΕ
      ΓΡΑΨΕ a[i]
    ΤΕΛΟΣ_ΑΝ
  ΤΕΛΟΣ_ΕΠΑΝΑΛΗΨΗΣ

! ΠΡΟΟΡΙΣΜΟΙ ΠΟΥ ΘΑ ΚΑΤΑΡΓΗΘΟΥΝ
  ΓΡΑΨΕ 'Θα καταργηθούν οι πτήσεις προς τους ακόλουθους προορισμούς.'
  ΓΙΑ i ΑΠΟ 1 ΜΕΧΡΙ 15
    ΑΝ mo[i] < 40 ΤΟΤΕ
      ΓΡΑΨΕ a[i]
    ΤΕΛΟΣ_ΑΝ
  ΤΕΛΟΣ_ΕΠΑΝΑΛΗΨΗΣ

! ΠΡΟΟΡΙΣΜΟΙ ΣΤΟΥΣ ΟΠΟΙΟΥΣ ΘΑ ΓΙΝΟΥΝ ΠΕΡΙΚΟΠΕΣ
  ΓΡΑΨΕ 'θα καταργηθούν οι πτήσεις προς τους ακόλουθους προορισμούς και τους αντίστοιχους μήνες.'
  ΓΙΑ i ΑΠΟ 1 ΜΕΧΡΙ 15
    ΑΝ mo[i] >= 40 ΚΑΙ mo[i] <= 65 ΤΟΤΕ
      ΓΡΑΨΕ '==========================='
      ΓΡΑΨΕ a[i]
      ΓΙΑ j ΑΠΟ 1 ΜΕΧΡΙ 12
        ΑΝ p[i,j] < 40 ΤΟΤΕ
          ΓΡΑΨΕ 'Μήνας' , j
        ΤΕΛΟΣ_ΑΝ
      ΤΕΛΟΣ_ΕΠΑΝΑΛΗΨΗΣ
    ΤΕΛΟΣ_ΑΝ
    ΓΡΑΨΕ '==========================='
    ΓΡΑΨΕ
  ΤΕΛΟΣ_ΕΠΑΝΑΛΗΨΗΣ                                      

ΤΕΛΟΣ_ΠΡΟΓΡΑΜΜΑΤΟΣ
 


Κορυφή
 Προφίλ  
 
Τελευταίες δημοσιεύσεις:  Ταξινόμηση ανά  
Δημιουργία νέου θέματος Απαντήστε στο θέμα  [ 1 Δημοσίευση ] 

Όλοι οι χρόνοι είναι UTC + 2 ώρες [ DST ]


Μέλη σε σύνδεση

Μέλη σε αυτή την Δ. Συζήτηση : Δεν υπάρχουν εγγεγραμμένα μέλη και 1 επισκέπτης


Δεν μπορείτε να δημοσιεύετε νέα θέματα σε αυτή τη Δ. Συζήτηση
Δεν μπορείτε να απαντάτε σε θέματα σε αυτή τη Δ. Συζήτηση
Δεν μπορείτε να επεξεργάζεστε τις δημοσιεύσεις σας σε αυτή τη Δ. Συζήτηση
Δεν μπορείτε να διαγράφετε τις δημοσιεύσεις σας σε αυτή τη Δ. Συζήτηση
Δεν μπορείτε να επισυνάπτετε αρχεία σε αυτή τη Δ. Συζήτηση

Αναζήτηση για:
Μετάβαση σε:  
cron
Προβολές σελίδων: website counters