Τώρα είναι Παρ 29 Μαρ 2024 01:41 pm

Όλοι οι χρόνοι είναι UTC + 2 ώρες [ DST ]




Δημιουργία νέου θέματος Απαντήστε στο θέμα  [ 1 Δημοσίευση ] 
Συγγραφέας Μήνυμα
ΔημοσίευσηΔημοσιεύτηκε: Δευτ 02 Φεβ 2004 02:18 am 
Χωρίς σύνδεση
Διαχειριστής

Εγγραφή: Παρ 28 Φεβ 2003 06:10 pm
Δημοσιεύσεις: 84
Syntax: [ Download ] [ Hide ]
! =============================================================
! Η τεχνική αυτή επιδεικνύει έναν τρόπο με τον οποίο
! μπορούν δύο ή περισσότερα ανεξάρτητα προγράμματα να
! συνεργάζονται μεταξύ τους. Με τη μέθοδο αυτή είναι
! δυνατόν ένα μεγάλο πρόγραμμα να σπάσει σε πολλά μικρότερα.
! Ο συνδετικός κρίκος μεταξύ των προγραμμάτων είναι τα
! αρχεία, που εδώ χρησιμοποιούνται σα χώρος προσωρινής
! αποθήκευσης των παραμέτρων κλήσης και των αποτελεσμάτων.
! Σε αυτό το παράδειγμα το "Αρχικό" πρόγραμμα δίνει τυχαίες
! τιμές σε έναν πίνακα και τον αποθηκεύει σε ένα αρχείο.
! Κατόπιν καλεί ένα άλλο πρόγραμμα ("Καλούμενο") το οποίο
! διαβάζει τον πίνακα από το αρχείο, τον ταξινομεί και τον
! αποθηκεύει πάλι. Έτσι, μετά την εκτέλεση του "Καλούμενου"
! προγράμματος, το "Αρχικό" μπορεί να διαβάσει τον
! ταξινομημένο πλέον πίνακα από το αρχείο.
!
! Στην έκδοση 6.3 επιλύθηκαν κάποια προβλήματα της εντολής
! ΕΚΤΕΛΕΣΕ και προστέθηκε ή δυνατότητα επιλογής του τρόπου
! κλήσης (ΣΕΙΡΙΑΚΗ_ΕΚΤΕΛΕΣΗ ή ΠΑΡΑΛΛΗΛΗ_ΕΚΤΕΛΕΣΗ).
!
! Για να δείτε τα αποτελέσματα αυτού του σχήματος, αποθηκεύστε
! τις εκτελέσιμες μορφές των δύο προγραμμάτων στον ίδιο φάκελο.
! Το exe του "Αρχικού" ονομάστε το "arxiko.exe" και του
! "Καλούμενου" ονομάστε το "kaloumeno.exe".
! Τέλος, κάντε διπλό κλικ στο "arxiko.exe".
! =============================================================


ΠΡΟΓΡΑΜΜΑ Αρχικό

ΜΕΤΑΒΛΗΤΕΣ
  ΑΚΕΡΑΙΕΣ: i, Π[10]
  ΑΡΧΕΙΑ ΑΚΕΡΑΙΩΝ: Α

ΑΡΧΗ

  ΣΥΣΧΕΤΙΣΕ_ΑΡΧΕΙΟ Α, 'params'
  ΔΗΜΙΟΥΡΓΗΣΕ_ΑΡΧΕΙΟ Α

  ΓΡΑΨΕ 'Αρχική μορφή του πίνακα:'
  ΓΙΑ i ΑΠΟ 1 ΜΕΧΡΙ 10
    Π[i] <-- ΤΥΧΑΙΟΣ(100)
    ΓΡΑΨΕ i, 'ο στοιχείο: ', Π[i]
    ΓΡΑΨΕ_ΑΡΧΕΙΟ Α, Π[i]
  ΤΕΛΟΣ_ΕΠΑΝΑΛΗΨΗΣ

  ΚΛΕΙΣΕ_ΑΡΧΕΙΟ Α
                              ! Αν χρησιμοποιούσαμε ΠΑΡΑΛΛΗΛΗ_ΕΚΤΕΛΕΣΗ το
  ΣΕΙΡΙΑΚΗ_ΕΚΤΕΛΕΣΗ           ! καλούμενο πρόγραμμα δε θα προλάβαινε να
  ΕΚΤΕΛΕΣΕ 'kaloumeno.exe'    ! κάνει την ταξινόμηση.
                              ! Η εντολή ΣΕΙΡΙΑΚΗ_ΕΚΤΕΛΕΣΗ μπορεί και να
                              ! παραληφθεί, αφού είναι ή προεπιλογή.
  ΑΝΟΙΞΕ_ΑΡΧΕΙΟ Α

  ΓΡΑΨΕ
  ΓΡΑΨΕ 'Ακολουθεί ο πίνακας όπως ταξινομήθηκε από το καλούμενο πρόγραμμα:'
  ΓΙΑ i ΑΠΟ 1 ΜΕΧΡΙ 10
    ΔΙΑΒΑΣΕ_ΑΡΧΕΙΟ Α, Π[i]
    ΓΡΑΨΕ i, 'ο στοιχείο: ', Π[i]
  ΤΕΛΟΣ_ΕΠΑΝΑΛΗΨΗΣ

  ΚΛΕΙΣΕ_ΑΡΧΕΙΟ Α
  ΔΙΑΓΡΑΨΕ_ΑΡΧΕΙΟ Α

ΤΕΛΟΣ_ΠΡΟΓΡΑΜΜΑΤΟΣ Αρχικό

 

Syntax: [ Download ] [ Hide ]
! =================================================
! Το πρόγραμμα αυτό δε λειτουργεί μόνο του, αλλά σε
! συνεργασία με το πρόγραμμα "Αρχικό".
! =================================================


ΠΡΟΓΡΑΜΜΑ Καλούμενο

ΜΕΤΑΒΛΗΤΕΣ
  ΑΚΕΡΑΙΕΣ: i, j, Π[10], temp
  ΑΡΧΕΙΑ ΑΚΕΡΑΙΩΝ: Α

ΑΡΧΗ

  ΣΥΣΧΕΤΙΣΕ_ΑΡΧΕΙΟ Α, 'params'
  ΑΝ ΥΠΑΡΧΕΙ_ΑΡΧΕΙΟ('params')=ΨΕΥΔΗΣ ΤΟΤΕ
    ΓΡΑΨΕ 'ΣΦΑΛΜΑ: Το αρχείο παραμέτρων δεν υπάρχει.'
    ΓΡΑΨΕ '        Αυτό το πρόγραμμα δεν πρέπει να εκτελείται μόνο του,'
    ΓΡΑΨΕ '        αλλά να καλείται από άλλο πρόγραμμα.'
    ΤΕΡΜΑΤΙΣΜΟΣ
  ΤΕΛΟΣ_ΑΝ

  ΑΝΟΙΞΕ_ΑΡΧΕΙΟ Α
  ΓΙΑ i ΑΠΟ 1 ΜΕΧΡΙ 10
    ΔΙΑΒΑΣΕ_ΑΡΧΕΙΟ Α, Π[i]
  ΤΕΛΟΣ_ΕΠΑΝΑΛΗΨΗΣ

  ΓΙΑ i ΑΠΟ 2 ΜΕΧΡΙ 10
    ΓΙΑ j ΑΠΟ 10 ΜΕΧΡΙ i ΜΕ ΒΗΜΑ -1
      ΑΝ Π[j-1]>Π[j] ΤΟΤΕ
        temp <-- Π[j-1]
        Π[j-1] <-- Π[j]
        Π[j] <-- temp
      ΤΕΛΟΣ_ΑΝ
    ΤΕΛΟΣ_ΕΠΑΝΑΛΗΨΗΣ
  ΤΕΛΟΣ_ΕΠΑΝΑΛΗΨΗΣ

  ΔΙΕΤΡΕΞΕ_ΑΡΧΕΙΟ Α, 1
  ΓΙΑ i ΑΠΟ 1 ΜΕΧΡΙ 10
    ΓΡΑΨΕ_ΑΡΧΕΙΟ Α, Π[i]
  ΤΕΛΟΣ_ΕΠΑΝΑΛΗΨΗΣ

  ΚΛΕΙΣΕ_ΑΡΧΕΙΟ Α
  ΚΛΕΙΣΕ_ΠΑΡΑΘΥΡΟ    ! Έτσι ή εκτέλεση θα είναι τελείως "διάφανη"

ΤΕΛΟΣ_ΠΡΟΓΡΑΜΜΑΤΟΣ Καλούμενο

 


Κορυφή
 Προφίλ  
Απάντηση με παράθεση  
Τελευταίες δημοσιεύσεις:  Ταξινόμηση ανά  
Δημιουργία νέου θέματος Απαντήστε στο θέμα  [ 1 Δημοσίευση ] 

Όλοι οι χρόνοι είναι UTC + 2 ώρες [ DST ]


Μέλη σε σύνδεση

Μέλη σε αυτή την Δ. Συζήτηση: Δεν υπάρχουν εγγεγραμμένα μέλη και 21 επισκέπτες


Δεν μπορείτε να δημοσιεύετε νέα θέματα σε αυτή τη Δ. Συζήτηση
Δεν μπορείτε να απαντάτε σε θέματα σε αυτή τη Δ. Συζήτηση
Δεν μπορείτε να επεξεργάζεστε τις δημοσιεύσεις σας σε αυτή τη Δ. Συζήτηση
Δεν μπορείτε να διαγράφετε τις δημοσιεύσεις σας σε αυτή τη Δ. Συζήτηση
Δεν μπορείτε να επισυνάπτετε αρχεία σε αυτή τη Δ. Συζήτηση

Αναζήτηση για:
Μετάβαση σε:  
cron
Προβολές: