Τώρα είναι Πέμ 28 Μαρ 2024 11:44 am

Όλοι οι χρόνοι είναι UTC + 2 ώρες [ DST ]




Δημιουργία νέου θέματος Απαντήστε στο θέμα  [ 1 Δημοσίευση ] 
Συγγραφέας Μήνυμα
 Θέμα δημοσίευσης: Εισφορές_Υπαλλήλων
ΔημοσίευσηΔημοσιεύτηκε: Κυρ 29 Φεβ 2004 03:32 pm 
Χωρίς σύνδεση

Εγγραφή: Κυρ 26 Οκτ 2003 02:28 pm
Δημοσιεύσεις: 3
Syntax: [ Download ] [ Hide ]
!===================================================================================================
!===================================================================================================
!
!Οι υπάλληλοι μιας εταιρίας συμφώνησαν για το μήνα Δεκέμβριο να κρατηθούν από το μισθό τους δύο ποσά
!ένα για τη διοργάνωση εκδηλώσεων στο χώρο της δουλείας τους τις ημέρες των γιορτών
!και ένα για τη βελτίωση του χώρου εργασίας τους (parking ιδιωτικό, θέρμανση, απολύμανση, κ.λ.π.)
!Ο υπολογισμός του ποσού των εισφορών εξαρτάται από τον αρχικό μισθό του υπαλλήλου
!και υπολογίζεται με βάση τα παρακάτω όρια μισθών:
!
!------------------------------------------------]
!===ΜΙΣΘΟΣ===========ΕΚΔΗΛΩΣΕΙΣ===ΒΕΛΤΙΩΣΗ_ΧΩΡΟΥ ]
! ΕΩΣ 600 ΕΥΡΩ      ||  3%            5%         ]
!  600,01 ΕΩΣ  900  ||  5%            7%         ]
!  900,01 ΕΩΣ 1300  ||  6%            9%         ]
! 1300,01 ΕΩΣ 1800  ||  7%           10%         ]
! ΠΑΝΩ ΑΠΟ 1800,01  ||  8%           12%         ]
!------------------------------------------------]
!
!Να διαβάζεται η ειδικότητα και
!αν είναι ΤΕΧΝΙΚΟΣ τοτε να προστίθεται 1% και 2% αντίστοιχα.
!Αν είναι ΠΩΛΗΤΗΣ προστίθεται 3% και 4% αντίστοιχα.
!Η συνολική προσφορά να μην ξεπερνά τα 700 Ευρώ.
!
!===================================================================================================
!===================================================================================================

ΠΡΟΓΡΑΜΜΑ Εισφορές_Υπαλλήλων

ΜΕΤΑΒΛΗΤΕΣ
  ΑΚΕΡΑΙΕΣ: Ειδικότητα, Π1, Π2, Π3, Π4
  ΠΡΑΓΜΑΤΙΚΕΣ: Α_Μισθός, Εισφορά1, Εισφορά2, Σ_Εισφορά, Τ_Μισθός
  ΧΑΡΑΚΤΗΡΕΣ: χ, β

ΑΡΧΗ
  ΑΡΧΗ_ΕΠΑΝΑΛΗΨΗΣ
    ΓΡΑΨΕ 'Μισθός Υπαλλήλου:'
    ΔΙΑΒΑΣΕ Α_Μισθός

    ΟΣΟ  (Α_Μισθός<=0) ΕΠΑΝΑΛΑΒΕ
      ΓΡΑΨΕ 'Ο μισθός δεν μπορεί να είναι αρνητικός ή μηδενικός αριθμός'
      ΓΡΑΨΕ 'Μισθός Υπαλλήλου:'
      ΔΙΑΒΑΣΕ Α_Μισθός
    ΤΕΛΟΣ_ΕΠΑΝΑΛΗΨΗΣ

    ΓΡΑΨΕ 'Αν ΤΕΧΝΙΚΟΣ, πατήστε 1'
    ΓΡΑΨΕ 'Αν ΠΩΛΗΤΗΣ,  πατηστε 2'
    ΓΡΑΨΕ 'Ειδάλλως,    πατήστε 3'
    ΔΙΑΒΑΣΕ Ειδικότητα



    ΑΝ  (Α_Μισθός<=600) ΤΟΤΕ
      Π1 <-- 3
      Π2 <-- 5
    ΑΛΛΙΩΣ_ΑΝ (Α_Μισθός<=900) ΤΟΤΕ
      Π1 <-- 5
      Π2 <-- 7
    ΑΛΛΙΩΣ_ΑΝ (Α_Μισθός<=1300) ΤΟΤΕ
      Π1 <-- 6
      Π2 <-- 9
    ΑΛΛΙΩΣ_ΑΝ (Α_Μισθός<=1800) ΤΟΤΕ
      Π1 <-- 7
      Π2 <-- 10
    ΑΛΛΙΩΣ
      Π1 <-- 8
      Π2 <-- 12
    ΤΕΛΟΣ_ΑΝ

    ΑΝ Ειδικότητα=1 ΤΟΤΕ
      Π1 <-- Π1+1
      Π2 <-- Π2+2
    ΑΛΛΙΩΣ_ΑΝ Ειδικότητα=2 ΤΟΤΕ
      Π1 <-- Π1+3
      Π2 <-- Π2+4
    ΤΕΛΟΣ_ΑΝ

    Εισφορά1 <-- Α_Μισθός*(Π1)/100
    Εισφορά2 <-- Α_Μισθός*(Π2)/100
    Σ_Εισφορά <-- Εισφορά1+Εισφορά2

    ΑΝ (Σ_Εισφορά>700) ΤΟΤΕ
      Σ_Εισφορά <-- 700
    ΤΕΛΟΣ_ΑΝ

    Τ_Μισθός <-- Α_Μισθός-Σ_Εισφορά
    ΓΡΑΨΕ 'Τελικός Μισθός: ', Τ_Μισθός, ' Ευρώ'
    ΓΡΑΨΕ ' '
    ΓΡΑΨΕ 'Για αναλυτικό λογαριασμό, πατήστε 1'
    ΔΙΑΒΑΣΕ χ


    ΑΝ χ='1' ΤΟΤΕ
      ΓΡΑΨΕ 'Επειδή ο αρχικός μισθός είναι: ', Α_Μισθός, ' Ευρώ,'

      ΑΝ Ειδικότητα=1 ΤΟΤΕ
        ΓΡΑΨΕ 'και ο υπάλληλος είναι ΤΕΧΝΙΚΟΣ'
      ΑΛΛΙΩΣ_ΑΝ Ειδικότητα=2 ΤΟΤΕ
        ΓΡΑΨΕ 'και ο υπάλληλος είναι ΠΩΛΗΤΗΣ'
      ΤΕΛΟΣ_ΑΝ

      ΓΡΑΨΕ 'οι εισφορές θα είναι:'
      ΓΡΑΨΕ 'Για εκδηλώσεις:                  ', (Π1/100), '%.'
      ΓΡΑΨΕ 'Άρα, ', Εισφορά1, ' Ευρώ'
      ΓΡΑΨΕ 'Για βελτίωση του χώρου εργασίας: ', (Π2/100), '%'
      ΓΡΑΨΕ 'Άρα,', Εισφορά2, ' Ευρώ'
      ΑΝ ((Εισφορά1+Εισφορά2)>700) ΤΟΤΕ
        ΓΡΑΨΕ 'Επειδή η συνολική εισφορά ξεπερνάει τα 700 Ευρώ,'
        ΓΡΑΨΕ 'Συνολική εισφορά: 700 Ευρώ'
      ΑΛΛΙΩΣ
        ΓΡΑΨΕ 'Συνολική εισφορά: ', Σ_Εισφορά, ' Ευρώ'
      ΤΕΛΟΣ_ΑΝ
      ΓΡΑΨΕ 'Άρα, ο τελικός μισθός είναι: ', Τ_Μισθός, ' Ευρώ'
    ΤΕΛΟΣ_ΑΝ

    ΓΡΑΨΕ ' '
    ΓΡΑΨΕ 'Επιθυμείτε να επαναλάβετε τη διαδικασία;'
    ΓΡΑΨΕ 'Αν ΟΧΙ τότε πατήστε 1'
    ΔΙΑΒΑΣΕ β
  ΜΕΧΡΙΣ_ΟΤΟΥ β='1'

ΤΕΛΟΣ_ΠΡΟΓΡΑΜΜΑΤΟΣ


Κορυφή
 Προφίλ  
Απάντηση με παράθεση  
Τελευταίες δημοσιεύσεις:  Ταξινόμηση ανά  
Δημιουργία νέου θέματος Απαντήστε στο θέμα  [ 1 Δημοσίευση ] 

Όλοι οι χρόνοι είναι UTC + 2 ώρες [ DST ]


Μέλη σε σύνδεση

Μέλη σε αυτή την Δ. Συζήτηση: Δεν υπάρχουν εγγεγραμμένα μέλη και 5 επισκέπτες


Δεν μπορείτε να δημοσιεύετε νέα θέματα σε αυτή τη Δ. Συζήτηση
Δεν μπορείτε να απαντάτε σε θέματα σε αυτή τη Δ. Συζήτηση
Δεν μπορείτε να επεξεργάζεστε τις δημοσιεύσεις σας σε αυτή τη Δ. Συζήτηση
Δεν μπορείτε να διαγράφετε τις δημοσιεύσεις σας σε αυτή τη Δ. Συζήτηση
Δεν μπορείτε να επισυνάπτετε αρχεία σε αυτή τη Δ. Συζήτηση

Αναζήτηση για:
Μετάβαση σε:  
cron
Προβολές: